10 REM > AFSFiler
   20 os%=FNfx(0,1)AND&FF:VDU10,8:A%=POS:VDU13:IFA%<50:MODE&87:IFHIMEM>&7C00:MODE&83:IFHIMEM>&4000:MODE&80
   30 IFHIMEM<&FFFF:HIMEM=FNfx(132,0)
   40 PROCinit:PRINT"AFSFiler v"ver$" by J.G.Harston"':ONERRORIFFNerr:END
   50 REPEAT:fs%=FNfs:X%=ctrl%:Y%=X%DIV256:IFPOS:PRINT
   60   VDU8:wdt%=POS+1:PRINT
   70   IFdrv$="":PRINTCHR$(D%+48)"> ";ELSEPRINT"["drv$"] ";
   80   csd%=home%:INPUTLINE""A$:PROCdo(FNs(A$))
   90 UNTIL0
  100 DEFPROCinit:ver$="1.31b"
  110 DIMctrl% 127,name% 255,data% 255,thisdir% &19FF,alloc% 511:X%=ctrl%:Y%=X%DIV256:diskrec%=0:IFos%=6:DIMdiskrec% 255
  120 D%=0:drv$="":path$="":title$="":curr%=-1:csd%=0:home%=0:inmem%=0:valid%=&30534641:map$="JesMap"
  130 den%=1:opt%=0:fullinf%=TRUE:d$=".":s$="/":IFos%AND-24:d$="/":s$=".":IFos%AND-32:d$="\"
  140 cmd$=":MOUNT:DIR:CAT:EX:INFO:TYPE:DUMP:COPY:BLOCK:INF:HELP:QUIT:"
  150 hlp$=":<drive>|<image>:<dir>|&<blocknum>:::(<file>):<file> [CTRLS]:<file> [7BIT]:<source> <dest> (<opts>):<blocknum>:FULL|SHORT:::<opts>:"
  160 ENDPROC
  170 DEFFNerr:OSCLI"FX229":IFPOS:PRINT
  180 REPORT:IFFNfs<>fs%:OSCLI"FX143,18,"+STR$fs%
  190 PROCCloseAll:A%=ERR<>17ANDERR<>28:PRINTLEFT$(" at line "+STR$ERL,ERR<128ANDA%):=INKEY-1ANDA%
  200 DEFPROCCloseAll
  210 out%=out%:IFout%:A%=out%:out%=0:CLOSE#A%
  220 dsk%=dsk%:IFdsk%:A%=dsk%:dsk%=0:CLOSE#A%
  230 ENDPROC
  240 DEFPROCdo(A$):IFA$="?":A$="HELP"
  250 IFLEFT$(A$,1)=";"ORA$="":ENDPROC
  260 IFLEFT$(A$,1)="*":OSCLIMID$(A$,2):ENDPROC
  270 IFLEFT$(A$,1)=".":A$="CAT "+MID$(A$,2)
  280 A%=INSTR(A$+" "," "):B$=FNuc(LEFT$(A$,A%-1)):A$=FNs(MID$(A$,A%+1))
  290 IFLENB$=1ANDINSTR("01234567",B$):drv$="":D%=VALB$AND(((os%<6)OR3)AND7):home%=0:ENDPROC
  300 A%=INSTR(cmd$,":"+B$+":"):IFA%=0:PRINT"Bad command":ENDPROC
  310 A%=EVAL("FN_"+B$+"(A$)"):ENDPROC
  320 DEFFNsyn(S$):IFA$="":PRINT"Syntax: "B$" "S$:=TRUEELSE=FALSE
  330 DEFFN_QUIT(A$):PRINT"Quit"
  340 ONERROREND
  350 IFos%>5:*QUIT
  360 END
  370 DEFFN_HELP(A$):p%=2:q%=2:REPEAT
  380   A%=INSTR(cmd$,":",p%):PRINTSPC2MID$(cmd$,p%,A%-p%);:p%=A%+1
  390   A%=INSTR(hlp$,":",q%):PRINTTAB(8)MID$(hlp$,q%,A%-q%):q%=A%+1
  400 UNTILp%>LENcmd$:=0
  410 DEFFN_OPT(A$):IFA$="":PRINT"OPT=";opt%'"1:"'"2:"'"4:"'"8:":=0
  420 opt%=VAL(A$):=0
  430 DEFFN_INF(A$):IFA$="":PRINT"Output "LEFT$("FULL",fullinf%);LEFT$("SHORT",NOTfullinf%)" .inf info":=0
  440 fullinf%=FNuc(A$)="S":=0
  450 DEFFN_MOUNT(A$):home%=0:IFLENA$<2:PROCdo(A$):=0ELSEdrv$=FNs(A$):D%=-1:=0
  460 DEFFN_CAT(A$):PROCLstDir(0):=0
  470 DEFFN_EX(A$):PROCLstDir(1):=0
  480 DEFFN_DIR(A$):curr%=-1:IFFNsyn("<dir>|&<blocknum>"):=TRUE
  490 IFLEFT$(A$,1)="&":A%=FNMount:home%=EVAL(FNuc(A$)):path$="&"+FNh0(home%,6):=0
  500 IFINSTR(A$,".")+INSTR(A$,"^"):PRINT"DIR <Unsupported>":=TRUE
  510 IFA$="$":A%=FNMount:home%=root%:path$="$":=0
  520 IFFNlook:=TRUE
  530 IF(fptr%?&14AND&20)=0:PRINT"'"src$"' not a directory":=TRUE
  540 A%=fptr%?&C:fptr%?&C=13:path$=path$+"."+FNs($(fptr%+2)):fptr%?&C=A%
  550 home%=fptr%!&17AND&FFFFFF
  560 =0
  570 DEFFN_BLOCK(A$):IFFNsyn("<blocknum>"):=TRUE
  580 blk%=EVAL("&"+FNuc(A$))AND&FFFFFF:PROCRdBlocks(data%,blk%,D%,1):S%=blk%*256:O%=data%:ln%=256:PROCdump
  590 =0
  600 DEFFN_DUMP(A$):IFFNsyn("<fsp>"):=TRUE
  610 IFFNlook:=TRUE
  620 PROCFileInfo(fptr%,1):S%=0:REPEAT:PROCReadData:PROCdump:UNTILeof%
  630 =0
  640 DEFPROCdump:cols%=16:IFwdt%<80:cols%=8
  650 FORP%=0TOln%-1STEPcols%:B$=""
  660   PRINTFNh0(P%+S%,8)" ";:FORQ%=P%TOP%+cols%-1
  670     IFQ%<ln%:PRINTFNh0(?O%,2)" ";ELSE?O%=32:PRINTSPC3;
  680     A$=CHR$(?O%AND&7F):IFA$>=" "ANDA$<="~" B$=B$+A$ELSEB$=B$+"."
  690 O%=O%+1:NEXT:PRINTB$:NEXT:S%=S%+ln%:ENDPROC
  700 DEFFN_TYPE(A$):IFFNsyn("<fsp>"):=TRUE
  710 msk%=INSTR(A$," [")<>0:msk%=(msk%AND&80)OR&7F:A$=LEFT$(A$,INSTR(A$+" "," ")-1)
  720 IFFNlook:=TRUE
  730 PROCFileInfo(fptr%,1):P%=0:S%=0:last%=0:REPEAT:PROCReadData
  740   FORP%=0TOln%-1:Q%=?O%ANDmsk%:IFmsk%=255:VDUQ%ELSEIFQ%=10ORQ%=13ORQ%>31VDUQ%
  750     IF(Q%=10ORQ%=13)ANDQ%<>last%:VDU23-Q%
  760     IFQ%=9:PRINTSPC(8-(POSMOD8));
  770   last%=?O%:O%=O%+1:NEXT:S%=S%+ln%
  780 UNTILeof%:IFPOS:PRINT
  790 =0
  800 DEFFN_INFO(A$)
  810 IFA$<>"":IFFNlook:=TRUE
  820 IFA$<>"":x%=0:PROCListFile(1):=0
  830 IFFNMount:=TRUE
  840 PRINT"Disk: L";den%-(den%<>3);"FS::"title$;SPC(18-LENtitle$);MID$("SEQSEQINT",den%*3-2,3)" DEN=";den%
  850 PRINT"Root: &"FNh0(root%,6)"  CrDate: "FNdate(idate%)
  860 PRINT"MapA: &"FNh0(mapa%,6);MID$("* ",(mapa%=map%)+2,1)" ";
  870 PRINT"MapB: &"FNh0(mapb%,6);MID$("* ",(mapb%=map%)+2,1)" ";
  880 PRINT"MapSz:  ";mapsz%'"Size: &"FNh0(dsize%,6)"  ";dsize%DIV4;"K  ";(dsize%AND-512)/4096;"M"
  890 =0
  900 DEFFN_COPY(A$):IFFNsyn("<afs0 source> (inf:)<host dest> (<C>onfirm)"):=TRUE
  910 A%=INSTR(A$+" "," "):src$=LEFT$(A$,A%-1):dst$=FNs(MID$(A$,A%+1))
  920 cnf%=FNuc(RIGHT$(dst$,2))=" C":IFcnf%:dst$=FNs(LEFT$(dst$,LENdst$-2))
  930 inf%=FNuc(LEFT$(dst$,4))="INF:":IFinf%:dst$=MID$(dst$,5)
  940 IFdst$="":PRINT"<dest> missing":=TRUE
  950 IFos%<6:IFINSTR(dst$,"::")ORLEFT$(dst$,1)="-":PRINT"FS prefix unsupported":=TRUE
  960 A$=src$:IFA$<>"$":IFFNlook:=TRUE
  970 IFsrc$="$":A%=FNMount:fptr%=data%:fptr%?&14=&20:fptr%!&17=root%:curr%=-1:IFA%<0:=TRUE
  980 IF((fptr%?&14)AND&20)=0:leaf$=src$:PROCCopyOneFile(src$,dst$):=0
  990 A%=FNfile(dst$,8):dst$=dst$+d$
 1000 oldcsd%=csd%:oldfptr%=fptr%:curr%=-1:csd%=fptr%!&17AND&FFFFFF:PROCCopyDirectory(dst$)
 1010 A%=LENdst$:REPEATA%=A%-1:UNTILMID$(dst$,A%,1)=d$ORA%<1ORsrc$="$":dst$=LEFT$(dst$,A%)
 1020 IFsrc$="$":load%=0:exec%=0:length%=&200:attr%=8:mdate%=idate%:PROCSetInfo(dst$):=0
 1030 PROCSetDir:=0
 1040 DEFPROCCopyDirectory(dst$):LOCALentry%,leaf$
 1050 PROCRdDir:fptr%=thisdir%:IFthisdir%?15=0:ENDPROC
 1060 entry%=1:REPEAT:fptr%=thisdir%+(!fptr%AND&FFFF):PROCCopyObject
 1070 entry%=entry%+1:UNTILentry%>thisdir%?15
 1080 ENDPROC
 1090 DEFPROCCopyObject:LOCALoldcsd%,oldfptr%
 1100 PROCFileInfo(fptr%,1):IFfname$="":ENDPROC
 1110 IFcnf%:PRINT"Copy "fname$;:cnf%=FNyna(cnf%):IFcnf%>0:PRINT:ENDPROCELSEVDU13
 1120 leaf$=fname$:fname$=FNfn_todos(fname$)
 1130 IF((fptr%?&14)AND&20)=0:PROCCopyOneFile(fname$,dst$+fname$):ENDPROC
 1140 PRINT"Copying "fname$;SPC(10-LENfname$)" to "dst$+fname$
 1150 oldcsd%=csd%:oldfptr%=fptr%
 1160 curr%=-1:csd%=fptr%!&17AND&FFFFFF
 1170 A%=FNfile(dst$+fname$,8)
 1180 PROCCopyDirectory(dst$+fname$+d$)
 1190 PROCSetDir:ENDPROC
 1200 DEFPROCSetDir
 1210 curr%=-1:csd%=oldcsd%:PROCRdDir:fptr%=oldfptr%
 1220 PROCFileInfo(fptr%,1):PROCSetInfo(dst$+fname$)
 1230 ENDPROC
 1240 DEFPROCCopyOneFile(src$,dst$)
 1250 PRINT"Copying "src$;SPC(10-LENsrc$)" to "dst$;SPC4;
 1260 PROCFileInfo(fptr%,1):IFFNfile(dst$,5):X%!14=&33:A%=FNfile(dst$,4)
 1270 X%!2=load%:X%!6=exec%:X%!10=0:X%!14=&4000:A%=FNfile(dst$,7)
 1280 IFlength%:PROCCopyData
 1290 PROCSetInfo(dst$):PRINTSTRING$(3,CHR$127)
 1300 ENDPROC
 1310 DEFPROCCopyData
 1320 out%=FNf_openout(dst$):S%=0:REPEAT:PROCReadData:IFPOS=0:PRINTSPC4;
 1330   IF(S%AND1023)=0:PRINTSTRING$(3,CHR$8)FNd0(100*S%DIVlength%,2)"%";
 1340   IFln%:PROCgbpb(2,out%,data%,ln%,0):S%=S%+ln%
 1350 UNTILeof%:CLOSE#out%:out%=0:length%=S%
 1360 ENDPROC
 1370 DEFPROCSetInfo(dst$):X%!2=load%:X%!6=exec%:X%!10=length%:X%!14=attr%:A%=FNfile(dst$,1)
 1380 A$=leaf$+STRING$(11-LENleaf$," ")+FNh0(load%,8)+" "+FNh0(exec%,8)+" "+FNh0(length%,8)
 1390 IFfullinf%:A$=A$+" "+FNh0(attr%AND255,2)+" "+FNh0(mdate%,4)
 1400 A$=A$+CHR$13+CHR$10
 1410 IFinf%:out%=OPENOUT(dst$+s$+"inf"):FORp%=1TOLENA$:BPUT#out%,ASCMID$(A$,p%,1):NEXT:CLOSE#out%:out%=0
 1420 IFfs%<>5:ENDPROC
 1430 A%=FNNetFS_Op(19,CHR$4+CHR$access%+dst$)
 1440 X%!8=mdate%:A%=FNNetFS_OpN(19,5,10,dst$)
 1450 IFFNNetFS_Op(18,CHR$64+dst$):ENDPROC
 1460 X%!8=mdate%:X%!10=0:X%!13=mdate%:X%!15=0
 1470 A%=FNNetFS_OpN(19,64,18,dst$)
 1480 ENDPROC
 1490 DEFPROCLstDir(cflg%):x%=0:IFFNMount:PRINT"Not an AFS0 disk":ENDPROC
 1500 PRINT"Path: L";den%-(den%<>3);"FS::"title$"."path$'
 1510 PROCRdDir:fptr%=thisdir%:IFthisdir%?15=0:ENDPROC
 1520 FORentry%=1TOthisdir%?15
 1530   fptr%=thisdir%+(!fptr%AND&FFFF):PROCListFile(cflg%)
 1540 NEXTentry%:IFPOS:PRINT
 1550 ENDPROC
 1560 DEFPROCListFile(cflg%)
 1570 PROCFileInfo(fptr%,cflg%):PRINTfname$;SPC(11-LENfname$);
 1580 IF(cflg%AND1):PRINTFNh0(load%,8)" "FNh0(exec%,8)" "FNh0(length%,6)" ";
 1590 PRINTFNattr(access%);
 1600 IF(cflg%AND1):PRINTFNdate(mdate%)" "FNh0(sin%,6):ENDPROC
 1610 x%=x%+1:IFx%<(wdt%+1)DIV20:PRINT" ";ELSEx%=0:PRINT
 1620 ENDPROC
 1630 DEFFNattr(A%):A$=""
 1640 IF(A%AND1):A$="r"+A$
 1650 IF(A%AND2):A$="w"+A$
 1660 A$="/"+A$
 1670 IF(A%AND4):A$="R"+A$
 1680 IF(A%AND8):A$="W"+A$
 1690 IF(A%AND16):A$="L"+A$
 1700 IF(A%AND32):A$="D"+A$
 1710 IF(A%AND64):A$="P"+A$
 1720 IF(A%AND128):A$="M"+A$
 1730 =A$+STRING$(8-LENA$," ")
 1740 DEFFNdate(A%)=FNd0(A%AND31,2)+"/"+FNd0((A%DIV256)AND15,2)+"/"+FNd0(1981+(A%DIV4096)+((A%AND&E0)/2),4)
 1750 DEFFNlook:src$=A$:fptr%=FNfind(src$):IFfptr%:=FALSE
 1760 PRINT"'"src$"' not found":=TRUE
 1770 DEFFNfind(A$):match$=FNuc(LEFT$(A$,10)):match%=0:IFFNMount:=0
 1780 PROCRdDir:fptr%=thisdir%:entry%=1:IFthisdir%?15=0:=0
 1790 REPEAT:fptr%=thisdir%+(!fptr%AND&FFFF)
 1800   A%=fptr%?&C:fptr%?&C=13:fname$=FNs($(fptr%+2)):fptr%?&C=A%
 1810   match%=(FNuc(fname$)=match$):entry%=entry%+1
 1820 UNTILentry%>thisdir%?15ORmatch%
 1830 IFmatch%:=fptr%ELSE=0
 1840 DEFPROCFileInfo(f%,i%)
 1850 A%=f%?&C:f%?&C=13:fname$=FNs($(f%+2)):f%?&C=A%
 1860 FORA%=1TOLENfname$:IFMID$(fname$,A%,1)<"!"ORMID$(fname$,A%,1)>"~":fname$=""
 1870 NEXTA%
 1880 load%=f%!&0C:exec%=f%!&10:access%=f%?&14:mdate%=f%!&15AND&FFFF:sin%=f%!&17AND&FFFFFF
 1890 length%=0:attr%=(access%AND3)*16+(access%AND&C)/4+(access%AND16)/2+mdate%*256
 1900 IF(i%AND1)=0ORsin%=0:ENDPROC
 1910 IFden%=1:PROCFileLen1:ENDPROCELSEPROCFileLen2:ENDPROC
 1920 DEFPROCFileLen1
 1930 offset%=sin%:REPEAT
 1940   offset%=(offset%AND&FFF)*2+5
 1950   PROCRdAlloc(map%+offset%DIV256,2)
 1960   offset%=alloc%!(offset%AND255)AND&FFFF
 1970 length%=length%+256:UNTILoffset%AND&4000
 1980 A%=offset%AND255:IFA%:length%=length%+A%-256
 1990 ENDPROC
 2000 DEFPROCFileLen2
 2010 PROCRdAlloc(sin%,1):IFFNChkMap(alloc%):PRINT"Bad map":ENDPROC
 2020 B%=alloc%?8:IFB%:length%=B%-256
 2030 REPEAT
 2040   A%=12:REPEAT:B%=alloc%!A%AND&FFFF00:length%=length%+B%:A%=A%+5:UNTILB%=0ORA%>&F9
 2050   IFA%>&F9:B%=alloc%!250AND&FFFFFF:IFB%:PROCRdAlloc(B%,1)
 2060 UNTILB%=0
 2070 ENDPROC
 2080 DEFPROCRdDir:IFcurr%=csd%:ENDPROC
 2090 IFden%=1:PROCRdDir1ELSEPROCRdDir2
 2100 curr%=csd%:ENDPROC
 2110 DEFPROCRdDir1
 2120 addr%=thisdir%:fptr%=csd%:REPEAT
 2130   PROCRdBlocks(addr%,fptr%AND&FFF,D%,1)
 2140   offset%=(fptr%AND&FFF)*2+5
 2150   PROCRdAlloc(map%+offset%DIV256,2)
 2160   fptr%=alloc%!(offset%AND255)AND&FFFF
 2170 addr%=addr%+256:UNTIL(fptr%AND&4000)
 2180 ENDPROC
 2190 DEFPROCRdDir2
 2200 PROCRdAlloc(csd%,1):IFFNChkMap(alloc%):PRINT"Bad map":thisdir%?15=0:ENDPROC
 2210 addr%=thisdir%:fptr%=alloc%+10:REPEAT
 2220   PROCRdBlocks(addr%,!fptr%AND&FFFFFF,D%,fptr%!3AND&FFFF)
 2230   addr%=addr%+256*(fptr%!3AND&FFFF):fptr%=fptr%+5
 2240 UNTIL(!fptr%AND&FFFFFF)=0
 2250 ENDPROC
 2260 DEFFNMount:IFcsd%:=0
 2270 curr%=-1:home%=0:inmem%=0:bps%=256:den%=4:REPEAT:den%=den%-1:IFden%=1:spt%=10ELSEspt%=16
 2280   PROCfdcInit(diskrec%,8,spt%,2,den%+(den%=3),80,0):!data%=0:PROCRdBlocks(data%,0,D%,1)
 2290   IF!data%=valid%:den%=1
 2300   IFden%>1:!data%=0:PROCRdBlocks(data%,data%!&F6AND&FFFFFF,D%,1)
 2310 UNTILden%=1OR!data%=valid%
 2320 IF!data%=0:IFdrv$<>"":err%=-2
 2330 IFerr%=-2:PRINT"Disk error: image file not found":=-2
 2340 IF!data%<>valid%:=-5
 2350 path$="$":A%=data%?20:data%?20=13:title$=FNs($(data%+4)):data%?20=A%
 2360 freec%=data%!36AND&FFFF:idate%=data%!34AND&FFFF:root%=data%!31AND&FFFFFF:dnxt%=data%?29
 2370 mapsz%=data%?28:nsec%=data%!26AND&FFFF:ndsks%=data%?25:dsize%=data%!22AND&FFFFFF
 2380 ntrk%=data%!20AND&FFFF:mapb%=0:mapa%=0:map%=0:home%=root%:csd%=home%
 2390 IFden%>1:=0
 2400 mapsz%=data%?33:mapb%=data%!30AND&FFFFFF:mapa% =data%!27AND&FFFFFF
 2410 idate%=data%!25AND&FFFF:root%=data%!22AND&FFFFFF:dsize%=(data%!20AND&FFFF)*2
 2420 map%=mapa%:home%=root%:csd%=home%
 2430 PROCRdBlocks(data%,mapa%,D%,1):f%=?data%
 2440 PROCRdBlocks(data%,mapb%,D%,1):IF((f%-?data%)AND255)=255:map%=mapb%
 2450 =0
 2460 DEFPROCReadData
 2470 IFsin%=0:ln%=0:eof%=TRUE:ENDPROC
 2480 IFden%=1:PROCReadData1ELSEPROCReadData2
 2490 O%=data%:ENDPROC
 2500 DEFPROCReadData1
 2510 PROCRdBlocks(data%,sin%AND&FFF,D%,1)
 2520 offset%=(sin%AND&FFF)*2+5
 2530 PROCRdAlloc(map%+offset%DIV256,2)
 2540 sin%=alloc%!(offset%AND255)AND&FFFF
 2550 eof%=sin%AND&4000:ln%=256
 2560 IFeof%:ln%=sin%AND255:IFln%=0:ln%=256
 2570 ENDPROC
 2580 DEFPROCReadData2
 2590 eof%=0:IFS%=0:aptr%=0
 2600 IFaptr%=0:PROCRdAlloc(sin%,1):IFFNChkMap(alloc%):PRINT"Bad map":eof%=TRUE:ln%=0:ENDPROC
 2610 ln%=alloc%?8:REPEAT:IFaptr%<10:aptr%=10
 2620   sec%=alloc%!aptr%AND&FFFFFF
 2630   num%=alloc%!(aptr%+3)AND&FFFF
 2640   IFaptr%=250:PROCRdAlloc(sec%,1):alloc%?8=ln%:aptr%=0
 2650 UNTILaptr%:PROCRdBlocks(data%,sec%,D%,1)
 2660 sec%=sec%+1:num%=num%-1:alloc%!aptr%=sec%
 2670 alloc%?(aptr%+3)=num%:alloc%?(aptr%+4)=num%DIV256
 2680 ln%=256:IFnum%=0:aptr%=aptr%+5:IFalloc%!aptr%=0:eof%=TRUE:ln%=alloc%?8:IFln%=0:ln%=256
 2690 ENDPROC
 2700 DEFPROCRdAlloc(sin%,num%):IFsin%=inmem%:ENDPROC
 2710 PROCRdBlocks(alloc%,sin%,D%,num%):inmem%=sin%:ENDPROC
 2720 DEFFNChkMap(B%):A%=B%?6:B%?6=13:IF$B%=map$:B%?6=A%:=B%?6<>B%?255ELSEB%?6=A%:=TRUE
 2730 DEFPROCRdBlocks(addr%,block%,drive%,number%):LOCALp%
 2740 err%=0:FORp%=0TOnumber%-1:PROCfdcRd(addr%+p%*256,block%+p%,drive%,1,den%)
 2750 NEXT:ENDPROC
 2760 DEFPROCfdcInit(dskrec%,bps%,spt%,hds%,den%,trks%,sec0%)
 2770 LOCALi%:IFos%<>6:ENDPROC
 2780 dskrec%?0=bps%:dskrec%?1=spt%:dskrec%?2=hds%:dskrec%?3=den%:IFden%=1:dskrec%?2=1
 2790 FORi%=4TO59STEP4:dskrec%!i%=0:NEXT:dskrec%!60=&20000000:dskrec%!64=&20000000
 2800 dskrec%?8=sec0%:dskrec%!16=trks%*spt%*(2^bps%)*hds%
 2810 ENDPROC
 2820 DEFPROCfdcRd(addr%,sec%,drv%,num%,den%)
 2830 FORA%=0TO255STEP4:addr%!A%=0:NEXT:IFdrv%>7:err%=-1:ENDPROC
 2840 IFden%=3:IFsec%<&500:sec%=(sec%AND15)+((sec%AND&FFF0)*2)ELSEIFden%=3:sec%=(sec%AND15)+(((sec%AND&FFF0)-&500)*2)+&10
 2850 IFdrv$="":REPEAT:PROCfdcOp(1):addr%=addr%+256:sec%=sec%+1:num%=num%-1:UNTILnum%<1:ENDPROC
 2860 dsk%=FNf_openin(drv$):IFdsk%=0:err%=-2:ENDPROC
 2870 IFsec%*256>EXT#dsk%:CLOSE#dsk%:dsk%=0:err%=-3:PRINT"Disk error: past end of image":ENDPROC
 2880 PROCgbpb(3,dsk%,addr%,num%*256,sec%*256):CLOSE#dsk%:dsk%=0
 2890 ENDPROC
 2900 DEFPROCfdcOp(op%)
 2910 IFos%=6:SYS"XADFS_DiscOp",0,op%+64+(diskrec%<<6),sec%*bps%+((drv%AND3)<<29),addr%,bps%TOerr%
 2920 IFos%<6:IFden%=1:IFop%=1:err%=FNdisk(addr%,&53,(drv%AND3)+2*(sec%DIV800),(sec%DIV10)MOD80,sec%MOD10,1,den%)
 2930 IFos%<6:IFden%>1:IFop%=1:err%=FNscsi(addr%,&08,drv%,sec%,1)
 2940 IFcsd%=0:ENDPROC
 2950 IFerr%:IFPOS:PRINT
 2960 IFerr%=-1:PRINT"Unsupported":ENDPROC
 2970 IFerr%:PRINT"Disk error &"FNh0(err%,2)" at ";drv%":"FNh0(sec%,6)
 2980 ENDPROC
 2990 DEFFNfn_todos(A$):LOCALB%:IF(os%AND-32)=0:=A$
 3000 FORA%=1TOLENA$:B%=INSTR("/?<>+=;\",MID$(A$,A%,1)):IFB%:A$=LEFT$(A$,A%-1)+MID$(".#$^&@%~",B%,1)+MID$(A$,A%+1)
 3010 NEXT:=A$
 3020 DEFFNyna(A%):IFA%=0:=0
 3030 PRINT"? (Y/N/A)";:REPEAT:A%=INSTR("YAN",CHR$(GETAND&DF)):UNTILA%
 3040 PRINTSTRING$(7,CHR$127);MID$("YesAllNo ",A%*3-2,3);:=A%-2
 3050 DEFFNdisk(addr%,cmd%,drv%,trk%,sec%,num%,den%):LOCALfs%
 3060 fs%=FNfs:IFfs%<>4:*FX143,18,4
 3070 REPEATX%?0=drv%+den%*24+8:X%!1=addr%:X%?5=3-7*(cmd%>127)
 3080   X%?6=cmd%:X%?7=trk%:X%?8=sec%:X%?9=num%OR&20:A%=127:CALL&FFF1
 3090 A%=X%?(7+X%?5):UNTILA%<>&10:IFfs%<>4:OSCLI"FX143,18,"+STR$fs%
 3100 =A%
 3110 DEFFNscsi(addr%,cmd%,drv%,sect%,num%):LOCALfs%
 3120 fs%=FNfs:IFfs%<>8:*FX143,18,8
 3130 X%?0=0:X%!1=addr%:X%?5=cmd%:X%?6=drv%*32+((sect%AND&1F0000)DIV65536)
 3140 X%?7=((sect%AND&FF00)DIV256):X%?8=sect%:X%!9=num%:X%!11=0
 3150 A%=&72:CALL&FFF1:A%=?X%:IFfs%<>8:OSCLI"FX143,18,"+STR$fs%
 3160 =A%
 3170 DEFFNfx(A%,X%):LOCALY%:Y%=X%DIV256:=((USR&FFF4)AND&FFFF00)DIV256
 3180 DEFFNh0(A%,N%):=RIGHT$("0000000"+STR$~A%,N%)
 3190 DEFFNd0(A%,N%):=RIGHT$("00000000"+STR$A%,N%)
 3200 DEFFNs(A$):IFLEFT$(A$,1)=" ":REPEATA$=MID$(A$,2):UNTILLEFT$(A$,1)<>" "
 3210 IFRIGHT$(A$,1)=" ":REPEATA$=LEFT$(A$,LENA$-1):UNTILRIGHT$(A$,1)<>" "
 3220 =A$
 3230 DEFFNuc(A$):LOCALB$:IFA$="":=""
 3240 REPEATB$=B$+CHR$(ASCA$AND((A$<"@")OR&DF)):A$=MID$(A$,2):UNTILA$="":=B$
 3250 DEFFNfile(A$,A%):IFA%-8:IFPAGE<&FFFFF:$name%=A$:?X%=name%:X%?1=name%DIV256:=(USR&FFDD)AND&FF
 3260 A$=FNf_name(A$):IFA%=255ORA%=5:X%!14=OPENIN(A$):IFX%!14:X%!10=EXT#X%!14:CLOSE#X%!14:X%!14=&33
 3270 IFA%=255:IFX%?6=0:OSCLI"LOAD """+A$+""" "+STR$~X%!2:=1
 3280 IFA%=5:IFX%!14:=1ELSEIFA%=5:=0
 3290 IFA%=0:OSCLI"SAVE """+A$+""" "+STR$~X%!10+" "+STR$~X%!14:X%!10=X%!14-X%!10:=1
 3300 IFA%=7:OSCLI"SAVE """+A$+""" "+STR$~PAGE+"+"+STR$~X%!10:X%!10=X%!14-X%!10:=1
 3310 IFA%-8:=0
 3320 IF(os%AND-24):A$="mkdir "+A$ELSEA$="cdir "+A$
 3330 IFHIMEM>&FFFF:LOCALERROR:ONERRORLOCAL:=0
 3340 OSCLIA$:=2
 3350 DEFPROCgbpb(A%,chn%,addr%,num%,ptr%)
 3360 ?X%=chn%:X%!1=addr%:X%!5=num%:X%!9=ptr%:IFPAGE<&FFFFF:CALL&FFD1:ENDPROC
 3370 IFA%=1ORA%=3:PTR#?X%=X%!9
 3380 REPEAT:IFA%=1ORA%=2:BPUT#?X%,?X%!1ELSEIFA%=3ORA%=4:?X%!1=BGET#?X%
 3390 X%!1=X%!1+1:X%!5=X%!5-1:UNTIL(EOF#?X%ANDA%>2)ORX%!5<1:ENDPROC
 3400 DEFFNfs:IF(os%AND-32)=0:LOCALA%,Y%,E%:=(USR&FFDA)AND&FF
 3410 =29
 3420 DEFFNf_openin(A$)=OPENIN(FNf_name(A$))
 3430 DEFFNf_openout(A$)=OPENOUT(FNf_name(A$))
 3440 DEFFNf_name(A$):IFos%AND-32:LOCALA%,B%:REPEATB%=A%:A%=INSTR(A$,"\",A%+1):UNTILA%=0:IFINSTR(A$,".",B%)=0:A$=A$+"."
 3450 =A$
 3460 DEFFNNetFS_Op(A%,A$)=FNNetFS_OpN(A%,0,7,A$)
 3470 DEFFNNetFS_OpN(A%,T%,O%,A$):!X%=0:X%?1=O%+1+LENA$:X%!3=A%:X%?7=T%:$(X%+O%)=A$
 3480 IFHIMEM>&FFFF:SYS&60048,A%,X%+7,X%?1,120TOA%:IFA%=0:X%?3=0:=0
 3490 IFHIMEM>&FFFF:IFA%>&FFFF:X%?3=?A%:SYS&2002B,A%+4TO$(X%+4):=X%?3
 3500 A%=&14:CALL&FFF1:=X%?3