Prnt131HP

10 REM >Printer 1.31 HP DESKJET

20 REM (C)J.G.Harston

30 REM B/B+/E/M/C/A/T

40 :

50 MODE&83:IF HIMEM-TOP>5000 MODE&80

60 :

70 REM Settings for HP DeskJet Printer and compatibles

80 REM xxxx0$ is to turn an effect off, xxxx1$ is to turn it on

90 reset$=CHR$27+"E"+CHR$27+"&k2G" :REM reset printer, LF=>CR+LF

100 nlq0$="":nlq1$="" :REM NLQ off/on

110 bold0$=CHR$27+"(s0B":bold1$=CHR$27+"(s3B" :REM bold off/on

120 comp0$=CHR$27+"&l6D"+CHR$27+"(s10H":comp1$=CHR$27+"&l12D"+CHR$27+"(s24H"

130 :REM compressed off/on

140 doubl0$=CHR$27+"(s0B":doubl1$=CHR$27+"(s3B" :REM double strike off/on

150 super0$="":super1$="" :REM superscript off/on

160 sub0$="":sub1$="" :REM subscript off/on

170 wide0$=CHR$27+"(s"+CHR$10+"H":wide1$=CHR$27+"(s"+CHR$5+"H"

180 :REM wide off/on

190 high0$="":high1$="" :REM d/high off/on

200 dwi0$="":dwi1$="" :REM d/high&wide off/on

210 quad0$="":quad1$="" :REM quad off/on

220 ital0$=CHR$27+"(s0S":ital1$=CHR$27+"(s1S" :REM italics off/on

230 iFlg%=FALSE :REM Use codes/Add 128 for italics

240 charsel$=CHR$27+"(" :REM char set selection

250 USchar$=charsel$+"10U" :REM select US chars

260 UKchar$=charsel$+"1E" :REM select UK chars

270 pound$=UKchar$+"#"+USchar$:Ipound$=UKchar$+CHR$(35+128)+USchar$

280 under0$=CHR$27+"&d@":under1$=CHR$27+"&d1D" :REM underline off/on

290 font0$="" :REM Font 0

300 font1$="" :REM Font 1

310 font2$="" :REM Font 2

320 font3$="" :REM Font 3

330 lf%=1 :REM change this to lf%=1 if

340 :REM your printer doesn't do

350 :REM automatic LF after CR

360 :

370 high%=TRUE:prn%=FALSE:reset%=TRUE:pl%=66:l%=60:ff%=TRUE:ffl%=FALSE

380 rr%=82:ds%=1:nlq%=FALSE:pound%=TRUE:pound2%=TRUE:code%=FALSE:op%=TRUE

390 :

400 ON ERROR IF FNerr END

410 C%=0:under%=0:bold%=0:REPEAT:*.

420 PRINT"Press SHIFT-Escape to exit."

430 REPEAT:REPEAT:IF ADVAL(-4)<63 PRINT;63-ADVAL(-4);" bytes in printer buffer. ";ADVAL(-4);" bytes free."

440 INPUTLINE"File: "F$:IF LEFT$(F$,1)="*" OSCLIF$

450 UNTIL(LEFT$(F$,1)<>"*" AND F$<>"")

460 C%=OPENIN(F$):IF C%=0 PRINT"Can't open '"F$"'"'

470 UNTILC%<>0:prn%=FNyn("Printer",prn%)

480 REPEAT:INPUT"First page (1) "sp%

490 INPUT"Last page (255) "ep%:IF ep%<1 ep%=255

500 UNTILep%>=sp%

510 IFop% PROCoptions:op%=FALSE ELSE IFFNyn("Change options",FALSE) PROCoptions

520 CLS:IF prn% VDU2:IF reset% PROCprn(reset$)

530 IFprn% PROCprn(USchar$)

540 IFprn% ANDnlq% PROCprn(nlq1$)

550 IFcode% VDU23,128,0,0,8,4,254,4,8,0,23,129,0,0,&F8,8,&2A,&1C,8,0

560 IFsp%>1 VDU3

570 line%=0:page%=0:it%=0:PROCprn(STRING$(ll%," ")):REPEAT B%=BGET#C%

580 IFB%>31 AND B%<127 AND B%<>96:VDUB%+it% ELSE PROCchar(B%)

590 IF(B%=32 AND POS>rr%+ll%)OR(POS>78 AND rr%<80) PROCchar(13)

600 IFline%=l% ANDep% ANDpage%=ep%-1 VDU3

610 IFline%=l% MOVE 0,32:DRAW 1279,32:PROCcls:PROCprn(STRING$(ll%," ")):line%=0:page%=page%+1:IFsp%ANDpage%=sp%-1 CLS:PRINT"Printing from page ";sp%:VDU2:sp%=0

620 UNTILEOF#C%:CLOSE#C%:C%=0

630 IFprn% PROCcls:VDU3

640 IFline%=0 line%=l%:page%=page%-1

650 PRINT'"'"+F$+"' printed. ";page%+1;" pages with ";line%;" lines on the last page."

660 UNTIL0

670 DEFPROCoptions

680 high%=FNyn("Use VIEW highlight 2 as escape char",high%)

690 IFprn% reset%=FNyn("Reset printer",reset%)

700 REPEAT:PRINT"Printer page length (";pl%;:INPUT") "pl2%:IF pl2%<>0 pl%=pl2%

710 IFpl%<40 PRINT"Too short"

720 UNTILpl%>39

730 REPEAT:PRINT"Text page length (";l%;:INPUT") "l2%:IF l2%<>0 l%=l2%

740 IFl%<4 PRINT"Too short"

750 UNTILl%>3

760 ff%=FNyn("Force FF at end of page",ff%)

770 IF NOTff% AND l%<>pl% ffl%=FNyn("Send LFs to advance to next page",ffl%)

780 INPUT"Lefthand margin (RETURN for non, 79=max): "ll%:IF ll%>30 ll%=0

790 PRINT"Righthand margin (RETURN for non, ";79+ll%;:INPUT "=max): "rr%:IF rr%<30 rr%=82+ll%

800 PRINT"Line spacing (";ds%;:INPUT") "ds2%:IF ds2%<>0 ds%=ds2%

810 nlq%=FNyn("Set NLQ",nlq%)

820 pound%=FNyn("Convert CHR$96 (`) into pound symbols",pound%)

830 pound2%=FNyn("Convert CHR$163 (�) into pound symbols",pound2%)

840 code%=FNyn("Show codes",code%)

850 eol$=LEFT$(CHR$13+CHR$10,lf%+1)+STRING$(ll%," ")

860 ENDPROC

870 DEFPROCchar(B%):z%=0:IF B%=221 B%=9

880 IFB%=10:B%=13

890 IFB%=13 ANDcode%:PROCvdu(CHR$129+CHR$8)

900 IFB%=13 ANDprn%:PROCprn(eol$)

910 IFB%=13 ANDprn% ANDds%>1:FORz%=1 TO ds%:PROCprn(eol$):NEXT

920 IFB%=13:line%=line%+1:PROCvdu(CHR$13+CHR$10):ENDPROC

930 IFB%=12 ANDprn%:PROCcls:PROCprn(STRING$(ll%," ")):line%=l%:ENDPROC

940 IFB%=12:line%=l%:ENDPROC

950 IFB%=9 ANDcode%:PROCvdu(CHR$128+CHR$8)

960 IFB%=9 ANDprn%=0:PRINTSTRING$(8-((POS+1) MOD 8),CHR$9);:ENDPROC

970 IFB%=9:PRINTSPC(8-((POS+1) MOD 8));:ENDPROC

980 IFB%=&1C ANDprn% ANDunder%=0:PROCprn(under1$):under%=under%EOR 1:ENDPROC

990 IFB%=&1C ANDprn% ANDunder%=1:PROCprn(under0$):under%=under%EOR 1:ENDPROC

1000 IFB%=&1D ANDhigh%:PROCmark2:ENDPROC

1010 IFB%=&1D ANDprn% ANDbold%=0:PROCprn(bold1$):bold%=bold%EOR 1:ENDPROC

1020 IFB%=&1D ANDprn% ANDbold%=1:PROCprn(bold0$):bold%=bold%EOR 1:ENDPROC

1030 IFprn%ANDiFlg%IF(B%=96 ANDpound%)OR(B%=163 ANDpound2%) PROCprn(Ipound$):ENDPROC

1040 IFprn%IF(B%=96 ANDpound%)OR(B%=163 ANDpound2%) PROCprn(pound$):ENDPROC

1050 IFB%=96 OR B%=163:VDUB%+it%:ENDPROC

1060 IFB%=&1A AND(code%=0 ORprn%):VDU32:ENDPROC

1070 IFB%=&1A ANDcode%:PROCvdu(CHR$130):ENDPROC

1080 IFB%>159 ANDcode% ANDprn%=0:VDU9,8:COLOUR129:COLOUR0:VDUB-128:COLOUR1:COLOUR128:ENDPROC

1090 IFB%>126 ANDcode% ANDprn%=0:VDU9,9,9,9,9,8,8,8,8,8:COLOUR129:COLOUR0:PRINT"[";B;"]";:COLOUR1:COLOUR128:ENDPROC

1100 IFprn%=0 VDU9,9,8,8:COLOUR129:COLOUR0:VDU94,B%+64:COLOUR1:COLOUR128:ENDPROC

1110 ENDPROC

1120 DEFPROCcls

1130 IFpl%<l% ENDPROC

1140 IFff% PROCprn(CHR$12):ENDPROC

1150 IFlf% FORz%=line% TO pl%-1:PROCprn(CHR$10):NEXT

1160 ENDPROC

1170 DEFPROCmark2:B$=CHR$BGET#C%:IFprn%=0:ENDPROC

1180 IFB$="!":PROCprn(CHR$13):REPEATz%=BGET#C%:UNTILz%=13 ORz%=10:ENDPROC

1190 IFB$="B":PROCprn(bold1$):ENDPROC

1200 IFB$="b":PROCprn(bold0$):ENDPROC

1210 IFB$="C":PROCprn(comp1$):ENDPROC

1220 IFB$="c":PROCprn(comp0$):ENDPROC

1230 IFB$="D":PROCprn(doubl1$):ENDPROC

1240 IFB$="d":PROCprn(doubl0$):ENDPROC

1250 IFB$="I" ANDiFlg%:it%=128:ENDPROC

1260 IFB$="i" ANDiFlg%:it%=0:ENDPROC

1270 IFB$="I":PROCprn(ital1$):ENDPROC

1280 IFB$="i":PROCprn(ital0$):ENDPROC

1290 IFB$="N":PROCprn(nlq1$):ENDPROC

1300 IFB$="n":PROCprn(nlq0$):ENDPROC

1310 IFB$="Q":PROCprn(quad1$):ENDPROC

1320 IFB$="q":PROCprn(quad0$):ENDPROC

1330 IFB$="S":PROCprn(super1$):ENDPROC

1340 IFB$="s":PROCprn(super0$):ENDPROC

1350 IFB$="T":PROCprn(high1$):ENDPROC

1360 IFB$="t":PROCprn(high0$):ENDPROC

1370 IFB$="W":PROCprn(wide1$):ENDPROC

1380 IFB$="w":PROCprn(wide0$):ENDPROC

1390 IFB$="X":PROCprn(dwi1$):ENDPROC

1400 IFB$="x":PROCprn(dwi0$):ENDPROC

1410 IFB$="Y":PROCprn(sub1$):ENDPROC

1420 IFB$="y":PROCprn(sub0$):ENDPROC

1430 REM Upper case to set, lower case to release.

1440 REM Eg: This is *BBold*b and this is *Iin italics*i.

1450 REM Highlight 1 does underlining as usual.

1460 IFB$="0":PROCprn(font0$):ENDPROC

1470 IFB$="1":PROCprn(font1$):ENDPROC

1480 IFB$="2":PROCprn(font2$):ENDPROC

1490 IFB$="3":PROCprn(font3$):ENDPROC

1500 ENDPROC

1510 DEFFNerr:PRINT:VDU3:COLOUR1:COLOUR128:REPORT:IFC%:A%=C%:C%=0:CLOSE#A%

1520 PRINTERL:=ERR=17 AND INKEY-1

1530 DEFPROCvdu(A$):*FX3,4

1540 PRINTA$;:*FX3

1550 ENDPROC

1560 DEFPROCprn(A$):LOCAL z%

1570 FOR z%=1 TO LEN A$:VDU1,ASCMID$(A$,z%,1):NEXT

1580 ENDPROC

1590 DEFFNyn(A$,F%):LOCAL K%:PRINTA$;"? (";CHR$(78-11*F%);") ";

1600 REPEAT:K%=GET AND&DF:UNTILK%=89 OR K%=78 OR K%=F% OR K%=13:PRINTSTRING$(4,CHR$8);:IF K%=13 K%=78-11*F%

1610 IF K%=78:PRINT"No ":=FALSE

1620 IF K%=89:PRINT"Yes":=TRUE

1630 PRINTCHR$K%;" ":=K%