10 REM > UxFiler
   20 os%=FNfx(0,1)AND&FF:VDU10,8:A%=POS:VDU13:IFA%<50:MODE&87:IFHIMEM>&7C00:MODE&83:IFHIMEM>&4000:MODE&80
   30 IFHIMEM<&FFFF:HIMEM=FNfx(132,0)
   40 PROCinit:PROChdr:PRINT:ONERRORIFFNerr:END
   50 REPEAT:X%=ctrl%:Y%=X%DIV256:IFPOS:PRINT
   60   VDU8:wdt%=POS+1:PRINT
   70   IFdrv$="":PRINTCHR$(D%+48)"> ";ELSEPRINT"["drv$"] ";
   80   csd%=home%:INPUTLINE""A$:PROCdo(FNs(A$))
   90 UNTILFALSE
  100 DEFPROCinit:ver$="1.31b"
  110 DIMctrl% 127,name% 255,zp% 7,data% 511,data2% 511,ientry% 63,dir% 515,object% 63,thisdir% 63,diskrec% 255AND(os%=6)
  120 X%=ctrl%:Y%=X%DIV256:res%=0:D%=0:drv$="":path$="/":title$="":home%=-1:csd%=-1:fsv%=6
  130 fs%=FNfs:d$=".":s$="/":IFos%AND-24:d$="/":s$=".":IFos%AND-32:d$="\"
  140 cmd$=":MOUNT:DIR:CD:CAT:EX:LS:INFO:TYPE:DUMP:IMPORT:EXPORT:FREE:BLOCK:HELP:QUIT:"
  150 hlp$=":<drive>|<image>:<dir>|&<inode>:<dir>|&<inode>::::(<file>):<file> [CTRLS]:<file> [7BIT]:<host source> <unix dest> (<opts>):<unix source> <host dest> (<opts>)::<blocknum>:::"
  160 ENDPROC
  165 DEFPROChdr:PRINT"UxFiler v"ver$" by J.G.Harston":ENDPROC
  170 DEFFNerr:OSCLI"FX229":IFPOS:PRINT
  180 REPORT:IFFNfs<>fs%:OSCLI"FX143,18,"+STR$fs%
  190 PROCCloseAll:A%=ERR<>17ANDERR<>28:PRINTLEFT$(" at line "+STR$ERL,ERR<128ANDA%):=INKEY-1ANDA%
  200 DEFPROCCloseAll:in%=in%:IFin%:A%=in%:in%=0:CLOSE#A%
  210 out%=out%:IFout%:A%=out%:out%=0:CLOSE#A%
  220 dsk%=dsk%:IFdsk%:A%=dsk%:dsk%=0:CLOSE#A%
  230 ENDPROC
  240 DEFPROCdo(A$):IFA$="?":A$="HELP"
  250 IFLEFT$(A$,1)=";"ORA$="":ENDPROC
  260 IFLEFT$(A$,1)="*":OSCLIMID$(A$,2):ENDPROC
  270 IFLEFT$(A$,1)=".":A$="CAT "+MID$(A$,2)
  280 A%=INSTR(A$+" "," "):B$=FNuc(LEFT$(A$,A%-1)):A$=FNs(MID$(A$,A%+1))
  290 IFB$="COPY":PRINT"Use EXPORT or IMPORT":ENDPROC
  300 IFLENB$=1ANDINSTR("0123",B$):drv$="":D%=VALB$:home%=-1:ENDPROC
  310 A%=INSTR(cmd$,":"+B$+":"):IFA%=0:PRINT"Bad command":ENDPROC
  320 A%=EVAL("FN_"+B$+"(A$)"):ENDPROC
  330 DEFFNsyn(S$):IFA$="":PRINT"Syntax: "B$" "S$:=TRUEELSE=FALSE
  340 DEFFN_QUIT(A$):PRINT"Quit"
  350 ONERROREND
  360 IFos%>5:*QUIT
  370 END
  380 DEFFN_HELP(A$):PROChdr:p%=2:q%=2:REPEAT
  390   A%=INSTR(cmd$,":",p%):PRINTSPC2MID$(cmd$,p%,A%-p%);:p%=A%+1
  400   A%=INSTR(hlp$,":",q%):PRINTTAB(9)MID$(hlp$,q%,A%-q%):q%=A%+1
  410 UNTILp%>LENcmd$:=0
  420 DEFFN_MOUNT(A$):home%=-1:IFLENA$<2:PROCdo(A$):=0ELSEdrv$=A$:D%=-1:=0
  430 DEFFN_CAT(A$):PROCLstDir(0):=0
  440 DEFFN_EX(A$):PROCLstDir(1):=0
  450 DEFFN_LS(A$)=FN_EX(A$)
  460 DEFFN_CD(A$)=FN_DIR(A$)
  470 DEFFN_DIR(A$):curr%=-1:IFFNsyn("<dir>|&<inode>"):=TRUE
  480 IFLEFT$(A$,1)="&":A%=FNMount:home%=EVAL(FNuc(A$)):path$="&"+FNh0(home%,6):=0
  490 IFA$="/":A%=FNMount:home%=root%:path$="/":=0
  500 IFFNlook:=TRUE
  510 IF(mode%AND16384)=0:PRINT"'"src$"' not a directory":=TRUE
  520 path$=path$+fname$+"/":home%=ptr%
  530 IFRIGHT$(path$,3)="../":path$=LEFT$(path$,LENpath$-4):REPEAT:path$=LEFT$(path$,LENpath$-1):UNTILRIGHT$(path$,1)="/"ORpath$=""
  540 IFRIGHT$(path$,2)="./":path$=LEFT$(path$,LENpath$-2)
  550 =0
  560 DEFFN_BLOCK(A$):IFFNsyn("<blocknum>"):=TRUE
  570 blk%=EVAL("&"+FNuc(A$)):PROCRdBlocks(data%,blk%,D%,1):O%=data%:ln%=512:PROCdump(FALSE)
  580 =0
  590 DEFFN_DUMP(A$):IFFNsyn("<fsp>"):=TRUE
  600 IFFNlook:=TRUE
  610 PROCdump(TRUE)
  620 =0
  630 DEFPROCdump(F%):cols%=16:IFwdt%<80:cols%=8
  640 FORP%=0TOln%-1STEPcols%:B$=""
  650   PRINTFNh0(P%,6)" ";:IFF%:IF(P%AND&1FF)=0:PROCReadData(P%):O%=data%
  660   FORQ%=P%TOP%+cols%-1
  670     IFQ%<ln%:PRINTFNh0(?O%,2)" ";ELSE?O%=32:PRINTSPC3;
  680     A$=CHR$(?O%AND&7F):IFA$>=" "ANDA$<="~" B$=B$+A$ELSEB$=B$+"."
  690 O%=O%+1:NEXT:PRINTB$:NEXT:ENDPROC
  700 DEFFN_TYPE(A$):IFFNsyn("<fsp>"):=TRUE
  710 msk%=INSTR(A$," [")<>0:msk%=(msk%AND&80)OR&7F:A$=LEFT$(A$,INSTR(A$+" "," ")-1)
  720 IFFNlook:=TRUE
  730 last%=0:FORP%=0TOln%-1:IF(P%AND&1FF)=0:PROCReadData(P%):O%=data%
  740   Q%=?O%ANDmsk%:IFmsk%=255:VDUQ%ELSEIFQ%=10ORQ%=13ORQ%>31VDUQ%
  750   IF(Q%=10ORQ%=13)ANDQ%<>last%:VDU23-Q%
  760   IFQ%=9:PRINTSPC(8-(POSMOD8));
  770 last%=?O%:O%=O%+1:NEXT:IFPOS:PRINT
  780 =0
  790 DEFFN_FREE(A$):A%=FNMount
  800 PROCRdInode(0):PROCRdBlocks(dir%,1,D%,1):isize%=dir%!0AND&FFFF
  810 IFfsv%=6:fsize%=dir%!2AND&FFFF:nfree%=dir%!4AND&FFFF:ptr%=dir%!6AND&FFFF
  820 IFfsv%=7:fsize%=FNswap32(dir%!2):nfree%=dir%!6AND&FFFF:ptr%=FNswap32(dir%!8)
  830 free%=nfree%:REPEAT
  840   IFptr%:PROCRdBlocks(data%,ptr%,D%,1):IFdata%?1=0:free%=free%+data%?0-1
  850   IFptr%:IFfsv%=6:ptr%=data%!2AND&FFFF
  860   IFptr%:IFfsv%=7:ptr%=FNswap32(data%!2)
  870 UNTILptr%<2ORptr%>=fsize%:used%=fsize%-free%
  880 PRINT"Disk free: &"FNh0(free%,8)" blocks, &"FNh0(free%*512,8)" bytes, ";free%DIV2;"K"
  890 PRINT"Disk used: &"FNh0(used%,8)" blocks, &"FNh0(used%*512,8)" bytes, ";used%DIV2;"K"
  900 PRINT"Disk size: &"FNh0(fsize%,8)" blocks, &"FNh0(fsize%*512,8)" bytes, ";fsize%DIV2;"K"
  910 =0
  920 DEFFN_INFO(A$)
  930 IFA$="":PROCPrSBlock:=0
  940 IFFNlook:=TRUE
  950 inode%=ptr%:x%=0:PROCListFile(1)
  960 IFfsv%=6:FORp%=8TOisz%-1STEP2:PRINTFNh0(ientry%!p%,4)" ";:NEXT:PRINT
  970 IFfsv%=7:FORp%=12TO41STEP3:PRINTFNh0(FNswap24(ientry%!p%),6)" ";:NEXT:PRINT
  980 IFfsv%=7:FORp%=42TO48STEP3:PRINTFNh0(FNswap24(ientry%!p%),6)" ";:NEXT:PRINT
  990 =0
 1000 DEFFN_EXPORT(A$):IFFNsyn("<unix source> (inf:)<host dest> (<C>onfirm)"):=TRUE
 1010 A%=INSTR(A$+" "," "):src$=LEFT$(A$,A%-1):dst$=FNs(MID$(A$,A%+1))
 1020 cnf%=FNuc(RIGHT$(dst$,2))=" C":IFcnf%:dst$=FNs(LEFT$(dst$,LENdst$-2))
 1030 inf%=FNuc(LEFT$(dst$,4))="INF:":IFinf%:dst$=MID$(dst$,5)
 1040 IFdst$="":PRINT"<dest> missing":=TRUE
 1050 IFos%<6:IFINSTR(dst$,"::")ORLEFT$(dst$,1)="-":PRINT"FS prefix unsupported":=TRUE
 1060 A$=src$:IFA$<>"/":A%=FNlook:cblk%=ptr%:IFA%:=TRUE
 1070 IFA$="/":A%=FNMount:cblk%=root%:IFA%<0:=TRUE
 1080 PROCFileInfo(cblk%)
 1090 IF(mode%AND24576)<>16384:fptr%=ientry%:leaf$=src$:PROCCopyOneFile(src$,dst$):=0
 1100 A%=FNfile(dst$,8):dst$=dst$+d$:PROCCopyDirectory(dst$)
 1110 PROCMetaInfo(thisdir%):PROCAcornInfo
 1120 PROCSetInfo(LEFT$(dst$,LENdst$-1))
 1130 =0
 1140 DEFFN_IMPORT(A$):IFFNsyn("<host source> <unix dest>"):=TRUE
 1150 A%=INSTR(A$," "):src$=LEFT$(A$,A%-1):A$=MID$(A$,A%+1)
 1160 A%=INSTR(A$," "):dst$=LEFT$(A$,A%-1):A$=MID$(A$,A%+1)
 1170 ptr%=FNfind(dst$):IFptr%=0:PRINT"'"dst$"' not found":=TRUE
 1180 PROCFileInfo(ptr%)
 1190 in%=FNf_openin(src$):IFin%=0:PRINT"'"src$"' not found":=TRUE
 1200 ln%=EXT#in%:IFln%>length%:CLOSE#in%:in%=0:PRINT"Source file longer than dest":=TRUE
 1210 IFln%>1024*1024-1:CLOSE#in%:in%=0:PRINT"Can't 1M+ files yet":=TRUE
 1220 PRINT"Copying "src$;" to "dst$;SPC4;
 1230 FORP%=0TOln%-1:B%=0
 1240   IF(P%AND&1FF)=0:PROCf_gbpb(3,in%,data%,512,P%):PROCWriteData(P%):PRINTSTRING$(3,CHR$8)FNd(100*P%DIVlength%,2)"%";
 1250 NEXT:CLOSE#in%:in%=0:PRINTSTRING$(3,CHR$127)
 1260 =0
 1270 DEFPROCCopyDirectory(dst$):LOCALentry%,bit%,inode%,fptr%,fname$,blk%,dptr%,alloc%
 1280 FORA%=0TO63STEP4:thisdir%!A%=ientry%!A%:NEXT
 1290 alloc%=all0%
 1300 REPEAT
 1310   blk%=thisdir%!alloc%AND&FFFFFF:IFfsv%=6:blk%=blk%AND&FFFF
 1320   IFblk%:PROCCopyBlock
 1330   alloc%=alloc%+alsz%
 1340 UNTILblk%=0ORalloc%>almx%-1
 1350 ENDPROC
 1360 DEFPROCCopyBlock
 1370 PROCRdBlocks(dir%,blk%,D%,1):dptr%=dir%
 1380 REPEAT
 1390   inode%=!dptr%AND&FFFF
 1400   A%=dptr%?16:dptr%?16=13:fname$=$(dptr%+2)+CHR$0:dptr%?16=A%
 1410   fname$=LEFT$(fname$,INSTR(fname$,CHR$0)-1)
 1420   IFinode%THENPROCCopyObject
 1430   dptr%=dptr%+16
 1440 UNTILdptr%>=dir%+512
 1450 ENDPROC
 1460 DEFPROCCopyObject:LOCALptr%,bit%,old_cblk%,thisdir$,bitmap$,object$
 1470 IFfname$="."ORfname$="..":ENDPROC
 1480 IFcnf%:PRINT"Copy "fname$;:cnf%=FNyna(cnf%):IFcnf%>0:PRINT:ENDPROCELSEVDU13
 1490 PROCFileInfo(inode%):leaf$=fname$:fname$=LEFT$(FNfn_undos(fname$),10):fptr%=ientry%
 1500 IF(mode%AND24576)<>16384:PROCCopyOneFile(leaf$,dst$+fname$):ENDPROC
 1510 old_cblk%=cblk%
 1520 FORA%=0TO63:thisdir$=thisdir$+CHR$thisdir%?A%:NEXT
 1530 FORA%=0TO63:object$ =object$ +CHR$fptr%?A%:NEXT
 1540 cblk%=inode%
 1550 A%=FNfile(dst$+fname$,8)
 1560 PROCCopyDirectory(dst$+fname$+d$)
 1570 FORA%=0TO63:object%?A%=ASCMID$(object$,A%+1):NEXT
 1580 PROCMetaInfo(object%)
 1590 PROCAcornInfo:PROCSetInfo(dst$+fname$)
 1600 FORA%=0TO63:thisdir%?A%=ASCMID$(thisdir$,A%+1):NEXT
 1610 cblk%=old_cblk%:PROCRdBlocks(dir%,blk%,D%,1)
 1620 ENDPROC
 1630 DEFPROCCopyOneFile(src$,dst$):LOCALcblk%
 1640 PRINT"Copying "src$;SPC(15-LENsrc$)"to "dst$SPC4;
 1650 FORA%=0TO63STEP4:object%!A%=fptr%!A%:NEXT
 1660 PROCMetaInfo(object%):IFFNfile(dst$,5):X%?14=&33:A%=FNfile(dst$,4)
 1670 PROCAcornInfo:X%!2=load%:X%!6=exec%:X%!10=0:X%!14=length%:A%=FNfile(dst$,7)
 1680 IFlength%:PROCCopyData
 1690 PROCSetInfo(dst$):PRINTSTRING$(3,CHR$127):ENDPROC
 1700 DEFPROCCopyData
 1710 out%=FNf_openout(dst$):P%=0:REPEAT:PROCReadData(P%):IFPOS=0:PRINTSPC4;
 1720   IF(P%AND1023)=0:PRINTSTRING$(3,CHR$8)FNd(100*P%DIVlength%,2)"%";
 1730   num%=512:IFP%+num%>length%:num%=length%-P%
 1740 PROCf_gbpb(2,out%,data%,num%,0):P%=P%+512:UNTILP%>=length%
 1750 CLOSE#out%:out%=0:ENDPROC
 1760 DEFPROCSetInfo(dst$):X%!2=load%:X%!6=exec%:X%!10=length%:X%!14=attr%:A%=FNfile(dst$,1)
 1770 A$=leaf$+STRING$(15-LENleaf$," ")+FNh0(load%,8)+" "+FNh0(exec%,8)+" "+FNh0(length%,8)+CHR$13+CHR$10
 1780 IFinf%:out%=OPENOUT(dst$+s$+"inf"):FORp%=1TOLENA$:BPUT#out%,ASCMID$(A$,p%,1):NEXT:CLOSE#out%:out%=0
 1790 IFfs%<>5:ENDPROC
 1800 X%!8=cdate%:A%=FNNetFS_OpN(19,5,10,dst$)
 1810 IFFNNetFS_Op(18,CHR$64+dst$):ENDPROC
 1820 X%!8=cdate%:X%!10=ctime%:X%!13=mdate%:X%!15=mtime%
 1830 A%=FNNetFS_OpN(19,64,18,dst$)
 1840 A%=FNNetFS_Op(0,"ACCOUNT "+dst$+" "+STR$~acc%+" ("+STR$~aux%+")")
 1850 ENDPROC
 1860 DEFPROCLstDir(cflg%):x%=0:IFFNMount:PRINT"Not a UNIX disk":ENDPROC
 1870 PROCRdInode(csd%)
 1880 IF(ientry%?1AND(64+32))<>64THENPRINT"inode "FNh0(csd%,4)" is not a directory":ENDPROC
 1890 PRINT"Path: "path$
 1900 IF(cflg%AND1):PRINT"inode filename"SPC12"mode"SPC6"nd uid gid len   ctime"SPC4"mtime"SPC4"atime"
 1910 alloc%=all0%
 1920 REPEAT
 1930   blk%=ientry%!alloc%AND&FFFFFF:IFfsv%=6:blk%=blk%AND&FFFF
 1940   IFblk%:PROCListBlock
 1950   alloc%=alloc%+alsz%
 1960   IFalloc%<almx%:PROCRdInode(csd%)
 1970 UNTILblk%=0ORalloc%>almx%-1
 1980 IF(cflg%AND1)=0:IF(x%AND3):PRINT
 1990 ENDPROC
 2000 DEFPROCListBlock
 2010 PROCRdBlocks(dir%,blk%,D%,1):dptr%=dir%
 2020 REPEAT
 2030   inode%=!dptr%AND&FFFF
 2040   A%=dptr%?16:dptr%?16=13:fname$=$(dptr%+2)+CHR$0:dptr%?16=A%
 2050   fname$=LEFT$(fname$,INSTR(fname$,CHR$0)-1)
 2060   IFinode%:PROCListFile(cflg%)
 2070   dptr%=dptr%+16
 2080 UNTILdptr%>=dir%+512
 2090 ENDPROC
 2100 DEFPROCListFile(cflg%)
 2110 IF(cflg%AND1):PRINTFNh0(inode%,4)" ";
 2120 PROCFileInfo(inode%):PRINTfname$;SPC(15-LENfname$);
 2130 IF(cflg%AND1)=0:x%=x%+1:IFx%<wdt%DIV15:PRINT" ";ELSEIF(cflg%AND1)=0:x%=0:PRINT
 2140 IF(cflg%AND1)=0:ENDPROC
 2150 PRINTFNattr(mode%)" ";
 2160 PRINTFNh0(nlink%,2)" ";
 2170 PRINTFNh0(uid%,2)" ";
 2180 PRINTFNh0(gid%,2)" ";
 2190 PRINTFNd(length%,6);" ";
 2200 PRINTFNdate(cdate%);" "FNdate(mdate%);" "FNdate(adate%)
 2210 ENDPROC
 2220 DEFPROCPrSBlock
 2230 A%=FN_FREE("")
 2240 PRINT"UnixFS version:";SPC14;fsv%;" (";8*fsv%-32;"-bit)"
 2250 PRINT"isize: inode table size:"SPC5"&"FNh0(isize%,4)" blocks, max inode: &";~isize%*512/isz%
 2260 PRINT"in-core free blocks: &"FNh0(nfree%,4)
 2270 IFfsv%=6:fbk%=6:stp%=2:ino%=&CE:in1%=&197
 2280 IFfsv%=7:fbk%=8:stp%=4:ino%=&D0:in1%=&199
 2290 FORn%=fbk%TOino%-1STEPstp%:IFfsv%=6:PRINTFNh0(dir%!n%,4);ELSEIFfsv%=7:PRINTFNh0(FNswap32(dir%!n%),8);
 2300   IF(n%AND31)=4:PRINTCHR$8ELSEPRINT" ";
 2310 NEXT:PRINT
 2320 PRINT"in-core free inodes: &"FNh0(dir%!ino%,4)
 2330 FORn%=ino%+2TOin1%STEP2:PRINTFNh0(dir%!n%,4);:IF((n%-ino%-2)AND31)=30:PRINTCHR$8ELSEPRINT" ";
 2340 NEXT:PRINT
 2350 PRINT"flock: free list lock:"SPC7FNh0(dir%?(in1%+1),2);SPC8;
 2360 PRINT"ilock: inode table lock: "FNh0(dir%?(in1%+2),2)
 2370 PRINT"fmod:  superblock modified:  "FNh0(dir%?(in1%+3),2);SPC8;
 2380 PRINT"dlock: disk read only:"SPC3FNh0(dir%?(in1%+4),2)
 2390 PRINT"time:  disk last update:"SPC5FNdate(FNswap32(dir%!(in1%+5)))
 2400 FORn%=in1%+9TO&1FFSTEP2:PRINTFNh0(dir%!n%,4);:IF((n%-in1%-9)AND31)=30:PRINTCHR$8ELSEPRINT" ";
 2410 NEXT:IFPOS:PRINT
 2420 ENDPROC
 2430 DEFFNattr(A%):A$=""
 2440 IF(A%AND1)THENA$="x"ELSEA$="-"
 2450 IF(A%AND2)THENA$="w"+A$ELSEA$="-"+A$
 2460 IF(A%AND4)THENA$="r"+A$ELSEA$="-"+A$
 2470 IF(A%AND8)THENA$="x"+A$ELSEA$="-"+A$
 2480 IF(A%AND16)THENA$="w"+A$ELSEA$="-"+A$
 2490 IF(A%AND32)THENA$="r"+A$ELSEA$="-"+A$
 2500 IF(A%AND64)THENA$="x"+A$ELSEA$="-"+A$
 2510 IF(A%AND128)THENA$="w"+A$ELSEA$="-"+A$
 2520 IF(A%AND256)THENA$="r"+A$ELSEA$="-"+A$
 2530 IF(A%AND512)THENA$="s"+A$ELSEA$="-"+A$
 2540 IF(A%AND1024)THENA$="g"+A$ELSEA$="-"+A$
 2550 IF(A%AND2048)THENA$="u"+A$ELSEA$="-"+A$
 2560 IF(A%AND4096)THENA$="l"+A$ELSEA$="-"+A$
 2570 IF(A%AND8192)THENA$="c"+A$ELSEA$="-"+A$
 2580 IF(A%AND16384)THENA$="d"+A$ELSEA$="-"+A$
 2590 IF(A%AND32768)THENA$="a"+A$ELSEA$="-"+A$
 2600 =A$
 2610 DEFFNdate(A%)
 2620 LOCALday%,month%,year%,hour%,minute%,second%
 2630 X%!1=A%/2.56:X%!1=X%!1+&336E996A:PROCDate_ToOrd(X%)
 2640 =FNd0(day%,2)+"/"+FNd0(month%,2)+"/"+FNd0(year%,2)
 2650 DEFPROCUnixDateToAcorn(A%)
 2660 X%!1=A%/2.56:X%!1=X%!1+&336E996A:PROCDate_ToOrd(X%)
 2670 date%=&101:IFyear%>1980:date%=FNf_date(day%,month%,year%)
 2680 time%=FNf_time(hour%,minute%,second%)
 2690 ENDPROC
 2700 DEFPROCAcornInfo
 2710 attr%=(mode%AND256)DIV256+(mode%AND128)DIV64+(mode%AND64)DIV16
 2720 attr%=attr%+(((mode%AND32)/2)OR((mode%AND4)*4))+(((mode%AND16)*2)OR((mode%AND2)*16))+(((mode%AND8)*8)OR((mode%AND1)*64))
 2730 IFcdate%>mdate%:cdate%=mdate%
 2740 PROCUnixDateToAcorn(cdate%):cdate%=date%:ctime%=time%
 2750 PROCUnixDateToAcorn(mdate%):mdate%=date%:mtime%=time%
 2760 PROCDate_FromOrd(X%,day%,month%,year%,hour%,minute%,second%,0)
 2770 X%!5=&FFFFFF:IF(mode%AND&49):X%!5=&FFFFE6
 2780 load%=X%!4:exec%=!X%:attr%=attr%+256*mdate%:acc%=uid%:aux%=gid%
 2790 ENDPROC
 2800 DEFFNlook:src$=A$:ptr%=FNfind(src$):IFptr%:PROCFileInfo(ptr%):ln%=length%:=FALSE
 2810 PRINT"'"src$"' not found":=TRUE
 2820 DEFFNfind(A$):match$=LEFT$(A$,14):match%=0:IFFNMount:=0
 2830 PROCRdInode(csd%):IFcsd%=-1:csd%=root%
 2840 alloc%=all0%:match%=0
 2850 REPEAT
 2860   blk%=ientry%!alloc%AND&FFFFFF:IFfsv%=6:blk%=blk%AND&FFFF
 2870   IFblk%:PROCFileBlock
 2880   alloc%=alloc%+alsz%
 2890   IFNOTmatch%:IFalloc%<almx%:PROCRdInode(csd%)
 2900 UNTILblk%=0ORalloc%>almx%-1ORmatch%
 2910 IFmatch%:=inode%ELSE=0
 2920 DEFPROCFileBlock
 2930 PROCRdBlocks(dir%,blk%,D%,1):dptr%=dir%
 2940 REPEAT
 2950   inode%=!dptr%AND&FFFF
 2960   A%=dptr%?16:dptr%?16=13:fname$=$(dptr%+2)+CHR$0:dptr%?16=A%
 2970   fname$=LEFT$(fname$,INSTR(fname$,CHR$0)-1)
 2980   match%=fname$=match$
 2990   dptr%=dptr%+16
 3000 UNTILdptr%>=dir%+512ORmatch%
 3010 ENDPROC
 3020 DEFPROCFileInfo(f%):PROCRdInode(f%):PROCMetaInfo(ientry%):ENDPROC
 3030 DEFPROCMetaInfo(i%)
 3040 mode%  =i%!0AND&FFFF
 3050 nlink% =i%!2AND&FFFF:IFfsv%=6:nlink%=nlink%AND&FF
 3060 uid%   =i%!(2+usz%/2)AND&FFFF:IFfsv%=6:uid%=uid%AND&FF
 3070 gid%   =i%!(2+2*(usz%/2))AND&FFFF:IFfsv%=6:gid%=gid%AND&FF
 3080 IFfsv%=6:length%=FNswap24(i%!5)
 3090 IFfsv%=7:length%=FNswap32(i%!8)
 3100 IFfsv%=6:adate%=FNswap32(i%!tm%):mdate%=FNswap32(i%!(tm%+4)):cdate%=mdate%
 3110 IFfsv%=7:adate%=FNswap32(i%!(tm%+8)):mdate%=FNswap32(i%!(tm%+4)):cdate%=FNswap32(i%!tm%)
 3120 ENDPROC
 3130 DEFPROCRdInode(i%)
 3140 PROCRdBlocks(data%,2,D%,1)
 3150 PROCRdBlocks(data%,(&400+i%*isz%-isz%)DIV512,D%,1)
 3160 i%=(&400+i%*isz%-isz%)AND511
 3170 FORA%=0TOisz%-1STEP4:ientry%!A%=data%!(A%+i%):NEXT
 3180 ENDPROC
 3190 DEFFNMount:IFcsd%<>-1:=0
 3200 PROCfdcInit(diskrec%,9,9,2,2,80,1):PROCRdBlocks(data%,2,D%,1)
 3210 fsv%=6:isz%=32:root%=1:all0%=8:almx%=&18:alsz%=2:tm%=&18:usz%=2
 3220 IFdata%!8=0:fsv%=7:isz%=64:root%=2:all0%=13:almx%=&34:alsz%=3:tm%=&34:usz%=4
 3230 csd%=root%:home%=csd%:path$="/"
 3240 =0
 3250 DEFPROCReadData(ptr%):PROCTxData(FALSE):ENDPROC
 3260 DEFPROCWriteData(ptr%):PROCTxData(TRUE):ENDPROC
 3270 DEFPROCTxData(write%):LOCALp%
 3280 vec%=(mode%AND4096)<>0
 3290 IFfsv%=6:PROCTx6
 3300 IFfsv%=7:PROCTx7
 3310 IFp%=0:IFNOTwrite%:FORA%=0TO511STEP4:data%!A%=0:NEXT:ENDPROC
 3320 IFp%:PROCTxBlocks(data%,p%,D%,1,write%)
 3330 ENDPROC
 3340 DEFPROCTx7
 3350 IFptr%<&1400:p%=ptr%DIV512:p%=12+p%*3:p%=FNswap24(ientry%!p%):ENDPROC
 3360 IFptr%<&11400:p%=&2AELSEp%=&2D
 3370 p%=FNswap24(ientry%!p%):PROCRdBlocks(data2%,p%,D%,1)
 3380 IFptr%<&11400:ptr%=ptr%-&1400:p%=ptr%DIV512ELSEptr%=ptr%-&11400:p%=ptr%DIV(512*128):p%=FNswap32(data2%!(p%*4)):PROCRdBlocks(data2%,p%,D%,1):p%=(ptr%DIV512)AND127
 3390 p%=FNswap32(data2%!(p%*4))
 3400 ENDPROC
 3410 DEFPROCTx6
 3420 IFvec%=0:p%=8+2*(ptr%DIV512):p%=ientry%!p%:ENDPROC
 3430 p%=8+2*(ptr%DIV(128*1024))
 3440 PROCRdBlocks(data2%,ientry%!p%,D%,1)
 3450 p%=(ptr%DIV512)AND&FF:p%=data2%!(p%*2)
 3460 ENDPROC
 3470 DEFPROCRdBlocks(a%,b%,d%,n%):PROCTxBlocks(a%,b%,d%,n%,FALSE):ENDPROC
 3480 DEFPROCTxBlocks(addr%,block%,drive%,number%,write%):LOCALq%
 3490 err%=0:block%=block%AND&FFFFFF:IFfsv%=6:block%=block%AND&FFFF
 3500 FORq%=0TOnumber%-1:PROCfdcAct(2+(write%=0),addr%+q%*512,block%+res%+q%,drive%,1,0):NEXT
 3510 ENDPROC
 3520 DEFPROCfdcInit(dskrec%,bps%,spt%,hds%,den%,trks%,sec0%)
 3530 LOCALi%:IFos%<>6:ENDPROC
 3540 dskrec%?0=bps%:dskrec%?1=spt%:dskrec%?2=hds%:dskrec%?3=den%:IFden%=1:dskrec%?2=1
 3550 FORi%=4TO59STEP4:dskrec%!i%=0:NEXT:dskrec%!60=&20000000:dskrec%!64=&20000000
 3560 dskrec%?8=sec0%:dskrec%!16=trks%*spt%*(2^bps%)*hds%
 3570 ENDPROC
 3580 DEFPROCfdcAct(op%,ad%,sc%,dv%,nm%,dn%)
 3590 IFop%=1:FORA%=0TO511STEP4:ad%!A%=0:NEXT
 3600 IFdv%>1:err%=-1:ENDPROC
 3610 IFdrv$="":REPEAT:PROCfdcOp(op%):ad%=ad%+512:sc%=sc%+1:nm%=nm%-1:UNTILnm%<1:ENDPROC
 3620 IFop%=2:dsk%=FNf_openup(drv$):IFdsk%=0:err%=-2:ENDPROC
 3630 IFop%=1:dsk%=FNf_openin(drv$):IFdsk%=0:err%=-2:ENDPROC
 3640 IFop%=1:IFsc%*512>EXT#dsk%:CLOSE#dsk%:dsk%=0:err%=-3:PRINT"Disk error: past end of image":ENDPROC
 3650 PROCf_gbpb(5-op%*2,dsk%,ad%,nm%*512,sc%*512):CLOSE#dsk%:dsk%=0
 3660 ENDPROC
 3670 DEFPROCfdcOp(op%)
 3680 IFos%>6:err%=-1
 3690 IFos%=6:SYS"XADFS_DiscOp",,op%+(diskrec%<<6),sc%*512+((dv%AND3)<<29),ad%,512TOerr%
 3700 IFos%<6:trk%=sc%DIV9:trk%=trk%DIV2+80*(trk%AND1):err%=FNscsi(ad%,6+op%*2,dv%OR4,trk%*16+sc%MOD9+1,1)
 3710 IFcsd%=0:ENDPROC
 3720 IFerr%:IFPOS:PRINT
 3730 IFerr%=-1:PRINT"Unsupported":ENDPROC
 3740 IFerr%:PRINT"Disk error &"FNh0(err%,2)" at ";dv%":"FNh0(sc%,6)
 3750 ENDPROC
 3760 DEFFNswap24(A%):zp%!0=A%:zp%!3=A%:=zp%!1AND&FFFFFF
 3770 DEFFNswap32(A%):zp%!0=A%:zp%!4=A%:=zp%!2
 3780 DEFFNs(A$):IFLEFT$(A$,1)=" ":REPEATA$=MID$(A$,2):UNTILLEFT$(A$,1)<>" "
 3790 IFRIGHT$(A$,1)=" ":REPEATA$=LEFT$(A$,LENA$-1):UNTILRIGHT$(A$,1)<>" "
 3800 =A$
 3810 DEFFNuc(A$):IFA$="":=""
 3820 FORA%=1TOLENA$:IFMID$(A$,A%,1)>"_":A$=LEFT$(A$,A%-1)+CHR$(ASCMID$(A$,A%,1)AND&5F)+MID$(A$,A%+1)
 3830 NEXT:=A$
 3840 DEFFNfx(A%,X%):LOCALY%:Y%=X%DIV256:=(USR&FFF4AND&FFFF00)DIV256
 3850 DEFFNfn_undos(A$):LOCALB%:IF(os%AND-32):=A$
 3860 FORA%=1TOLENA$:B%=INSTR(".#$^&@%~",MID$(A$,A%,1)):IFB%:A$=LEFT$(A$,A%-1)+MID$("/?<>+=;\",B%,1)+MID$(A$,A%+1)
 3870 NEXT:=A$
 3880 DEFFNyna(A%):IFA%=0:=0
 3890 PRINT"? (Y/N/A)";:REPEAT:A%=INSTR("YAN",CHR$(GETAND&DF)):UNTILA%
 3900 PRINTSTRING$(7,CHR$127);MID$("YesAllNo ",A%*3-2,3);:=A%-2
 3910 DEFFNh0(A%,N%):=RIGHT$("00000000"+STR$~A%,N%)
 3920 DEFFNd0(A%,N%):=RIGHT$("00000000"+STR$A%,N%)
 3930 DEFFNd(A%,N%):=RIGHT$("         "+STR$A%,N%)
 3940 DEFFNscsi(addr%,cmd%,drv%,sect%,num%):LOCALfs%
 3950 fs%=FNfs:IFfs%<>8:*FADFS
 3960 X%?0=0:X%!1=addr%:X%?5=cmd%:X%?6=drv%*32+((sect%AND&1F0000)DIV65536)
 3970 X%?7=((sect%AND&FF00)DIV256):X%?8=sect%:X%!9=num%:X%!11=0
 3980 A%=&72:CALL&FFF1:A%=?X%:IFfs%<>8:OSCLI"FX143,18,"+STR$fs%
 3990 =A%
 4000 DEFFNfs:IF(os%AND-32)=0:LOCALA%,Y%,E%:=(USR&FFDA)AND&FF
 4010 =29
 4020 DEFPROCf_gbpb(A%,chn%,addr%,num%,ptr%)
 4030 ?X%=chn%:X%!1=addr%:X%!5=num%:X%!9=ptr%:IFPAGE<&FFFFF:CALL&FFD1:ENDPROC
 4040 IFA%=1ORA%=3:PTR#?X%=X%!9
 4050 REPEAT:IFA%=1ORA%=2:BPUT#?X%,?X%!1ELSEIFA%=3ORA%=4:?X%!1=BGET#?X%
 4060 X%!1=X%!1+1:X%!5=X%!5-1:UNTIL(EOF#?X%ANDA%>2)ORX%!5<1:ENDPROC
 4070 DEFFNfile(A$,A%):IFA%-8:IFPAGE<&FFFFF:$name%=A$:?X%=name%:X%?1=name%DIV256:=(USR&FFDD)AND&FF
 4080 A$=FNf_name(A$):IFA%=255ORA%=5:X%!14=OPENIN(A$):IFX%!14:X%!10=EXT#X%!14:CLOSE#X%!14:X%!14=&33
 4090 IFA%=255:IFX%?6=0:OSCLI"LOAD """+A$+""" "+STR$~X%!2:=1
 4100 IFA%=5:IFX%!14:=1ELSEIFA%=5:=0
 4110 IFA%=0:OSCLI"SAVE """+A$+""" "+STR$~X%!10+" "+STR$~X%!14:X%!10=X%!14-X%!10:=1
 4120 IFA%=7:OSCLI"SAVE """+A$+""" "+STR$~PAGE+"+"+STR$~X%!10:X%!10=X%!14-X%!10:=1
 4130 IFA%-8:=0
 4140 IF(os%AND-24):A$="mkdir "+A$ELSEA$="cdir "+A$
 4150 IFHIMEM>&FFFF:LOCALERROR:ONERRORLOCAL:=0
 4160 OSCLIA$:=2
 4170 DEFFNf_openin(A$)=OPENIN(FNf_name(A$))
 4180 DEFFNf_openout(A$)=OPENOUT(FNf_name(A$))
 4190 DEFFNf_openup(A$)=OPENUP(FNf_name(A$))
 4200 DEFFNf_name(A$):IFos%AND-32:LOCALA%,B%:REPEATB%=A%:A%=INSTR(A$,"\",A%+1):UNTILA%=0:IFINSTR(A$,".",B%)=0:A$=A$+"."
 4210 =A$
 4220 DEFFNNetFS_Op(A%,A$)=FNNetFS_OpN(A%,0,7,A$)
 4230 DEFFNNetFS_OpN(A%,T%,O%,A$):LOCALN%:!X%=0:X%?1=O%+1+LENA$:X%!3=A%:X%?7=T%:$(X%+O%)=A$
 4240 IFHIMEM>&FFFF:FORN%=4TOX%?1:X%?N%=X%?(N%+3):NEXT:SYS&60048,A%,X%+4,O%+LENA$,120TOA%:IFA%=0:X%?3=0:=0
 4250 IFHIMEM>&FFFF:IFA%>&FFFF:X%?3=?A%:SYS&2002B,A%+4TO$(X%+4):=X%?3
 4260 A%=&14:CALL&FFF1:=X%?3
 4270 DEFPROCDate_FromOrd(mem%,d%,m%,y%,hr%,mn%,sc%,cs%):y%=y%MOD400
 4280 d%=y%*365.25+m%*30+d%+VALMID$("120112234455",m%,1)+((y%MOD4)=0)-((y%-1)DIV100)-(m%>2AND((y%MOD4)=0AND(y%MOD100)<>0ORy%=0))+36493
 4290 IFd%>146066:d%=d%-146097
 4300 d%=d%*&41EB:mem%!1=d%+d%:d%=((hr%*60+mn%)*60+sc%)*100+cs%
 4310 ?mem%=d%:mem%!1=mem%!1+d%DIV256:ENDPROC
 4320 DEFPROCDate_ToOrd(mem%):LOCALA%,B%,C%,D%
 4330 year%=0:month%=0:day%=0:hour%=0:minute%=0:second%=0:centi%=0
 4340 IFmem%!1<0:ENDPROC
 4350 D%=mem%!1DIV&83D6+2447065:C%=mem%?0+256*(mem%!1MOD&83D6):centi%=C%MOD100
 4360 C%=C%DIV100:second%=C%MOD60:C%=C%DIV60:minute%=C%MOD60:hour%=C%DIV60
 4370 B%=((D%*4+3)MOD146097AND-4)+3:C%=B%MOD1461DIV4*5+2:D%=D%*4+3
 4380 A%=C%DIV153+2:day%=C%MOD153DIV5+1:month%=A%MOD12+1
 4390 year%=D%DIV146097*100+B%DIV1461+A%DIV12-4800
 4400 ENDPROC
 4410 DEFFNf_date(d%,m%,y%):y%=y%-1981:=d%+m%*256+(y%AND15)*4096+(y%DIV16)*32
 4420 DEFFNf_time(h%,m%,s%):=h%+m%*256+s%*65536