10 REM > FontDemo

   20 *FONTFX

   30 MODE 4

   40 DIM c% 15:X%=c%:Y%=X%DIV256:A%=10:?X%=169:X%!1=0:CALL&FFF1:A%=X%!1

   50 $c%="++++++++-|+":IFA%=&18181818:$c%="°±²³§«­®¦©¯"

   60 DIM style$(8):FOR A=0 TO 8:READ style$(A):NEXT A

   70 FOR style=0 TO 7

   80   PROCtable((2^style)DIV2)

   90 NEXT style

  100 FOR style=0 TO 127

  110   PROCtable(style)

  120   IF (style AND 63)=47:style=style+16

  130 NEXT style

  140 END

  150 :

  160 DEFPROCtable(style)

  170 VDU 30

  180 GCOL -ASC"s",0

  190 PRINT" Style ";style;":  "'" ";

  200 IF style=0:PRINT style$(0);

  210 FOR A=7 TO 0 STEP -1:IF style AND (2^A):PRINTstyle$(A+1);" ";

  220 NEXT A:PRINT SPC(40-POS);TAB(0,2);

  230 PRINT " ";CHR$c%?0;CHR$c%?8;CHR$c%?4;STRING$(33,CHR$c%?8);CHR$c%?1

  240 PRINT " ";CHR$c%?9;CHR$32;CHR$c%?9;" 0 1 2 3 4 5 6 7 8 9 A B C D E F ";CHR$c%?9

  250 PRINT " ";CHR$c%?5;CHR$c%?8;CHR$c%?10;STRING$(33,CHR$c%?8);CHR$c%?6

  260 FOR A=32 TO 127 STEP 16

  270   PRINT " ";CHR$c%?9;~A DIV 16;CHR$c%?9;" ";

  280   GCOL -ASC"s",style

  290   FOR B=A TO A+15

  300     IF B=127 VDU 32,32

  310   VDU B,32:NEXT

  320   GCOL -ASC"s",0

  330   VDU 127,32,c%?9:PRINT

  340 NEXT

  350 PRINT " ";CHR$c%?2;CHR$c%?8;CHR$c%?7;STRING$(33,CHR$c%?8);CHR$c%?3

  360 PRINT SPC(38)

  370 IF INKEY(200)

  380 ENDPROC

  390 :

  400 DATA Plain,Underline,Bold,Italics,Thin

  410 DATA Superscript,Subscript,Inverse,Wide