GSTrans.bbc

10 REM > GSTrans.bbc

20 REM GSTrans in BASIC

30 REM J.G.Harston

40 :

50 REPEAT

60 INPUT LINE "GSstring: "A$

70 A$=FNGS_Decode(A$,0)

80 A$=FNGS_Encode(A$)

90 PRINT A$

100 UNTIL FALSE

110 END

120 :

130 :

140 :

150 REM Decode a GSTrans string

160 REM On entry: inp$=GSTransed string

170 REM flg%=0 - parse whole string, *KEY style

180 REM =1 - parse until space, filename style (not implemented)

190 REM Returns: decoded string

200 DEFFNGS_Decode(inp$,flg%)

210 LOCAL out$,byte%,set%

220 IF LEFT$(inp$,1)=" ":REPEAT:inp$=MID$(inp$,2):UNTIL LEFT$(inp$,1)<>" "

230 IF LEFT$(inp$,1)="""":IF RIGHT$(inp$,1)="""":inp$=MID$(inp$,2,LENinp$-2)

240 IF inp$="":=""

250 REPEAT

260 byte%=-1:set%=0

270 IF LEFT$(inp$,2)="|!":set%=128:inp$=MID$(inp$,3)

280 IF LEFT$(inp$,1)="|":byte%=ASCMID$(inp$,2,1)AND31

290 IF LEFT$(inp$,2)="||":byte%=ASC"|"

300 IF LEFT$(inp$,2)="|?":byte%=127

310 IF LEFT$(inp$,2)="|""":byte%=34

320 IF LEFT$(inp$,2)="""""":byte%=34

330 IF byte%<0:byte%=ASC(inp$):inp$=MID$(inp$,2) ELSE inp$=MID$(inp$,3)

340 out$=out$+CHR$(set%+byte%)

350 UNTIL inp$=""

360 =out$

370 :

380 REM Encode into a GSTrans string

390 REM On entry: inp$=raw string

400 REM Returns: GSTrans string

410 DEFFNGS_Encode(inp$)

420 LOCAL out$,byte%

430 IF inp$="":=""""""

440 REPEAT

450 byte%=ASC(inp$):inp$=MID$(inp$,2)

460 IF byte%>127:out$=out$+"|!":byte%=byte% AND 127

470 IF byte%>31 AND byte%<>ASC"""" AND byte%<>ASC"|" AND byte%<>127:out$=out$+CHR$(byte%)

480 IF byte%<32:out$=out$+"|"+CHR$(byte%+64)

490 IF byte%=ASC"""":out$=out$+""""""

500 IF byte%=ASC"|":out$=out$+"||"

510 IF byte%=127:out$=out$+"|?"

520 UNTIL inp$=""

530 =""""+out$+""""

540 :

550 REM Encode a single byte

560 REM On entry: byte%=byte to encode

570 REM Returns: GSTrans string

580 DEFFNGS_Byte(byte%)

590 LOCAL out$

600 IF byte%>127:out$="|!":byte%=byte% AND 127

610 IF byte%>31 AND byte%<>ASC"""" AND byte%<>ASC"|" AND byte%<>127:out$=out$+CHR$(byte%)

620 IF byte%<32:out$=out$+"|"+CHR$(byte%+64)

630 IF byte%=ASC"""":out$=out$+"""""" :REM quote can be doubled

640 IF byte%=ASC"""":out$=out$+"|""" :REM quote can be escaped

650 IF byte%=ASC"|":out$=out$+"||"

660 IF byte%=127:out$=out$+"|?"

670 =out$

680 :

690 REM From BLib.Character library:

700 DEFFNgs(A%):IFA%>127:="|!"+FNgs(A%AND127)

710 IFA%<32ORA%=127:="|"+CHR$(A%EOR64)ELSE=LEFT$("|",A%=34ORA%=124)+CHR$A%