; Blocks.s - Blocked tape load and save
; J.G.Harston, 25 June 1986

; Saves and loads files in blocks of 256 bytes

; Block header:
; 00
; File type
; Filename
; Block length - 256+ for full block, <256 for last block
; Block start address
; Block extra address
;
; Block data:
; FF
; <data> as per length
;
; Block data if final block is not &00xx bytes long:
; 00
;

; On entry to SAVE:
;  START    = start address
;  LENGTH   = data length
;  HEADER+0 = file type
;  HEADER+1 = filename
;
; On entry to LOAD:
;  HEADER+0 = file type
;  HEADER+1 = filename
;

	ORG	#5B00
SAVE	JP	DO_SAVE		; Entry block
LOAD	JP	DO_LOAD

START	DEFW	0		; Data start
LENGTH	DEFW	0		; Data length
BLKLEN	DEFW	512		; Block length
HEADER	DEFS	17		; File header to save/load
HEADER2	DEFS	17		; Loaded header

DO_SAVE	LD	HL,(START)
	LD	(HEADER+13),HL	; Copy start address to header
SA_LOOP	LD	HL,(LENGTH)	; Get remaining length
	LD	DE,(BLKLEN)	; Prepare to save full BLKLEN bytes
	AND	A
	SBC	HL,DE		; Is remaining length<BLKLEN ?
	JR	NC,SA_LEN	; Still more blocks to save
	ADD	HL,DE		; HL=remaining amount to save
	LD	E,L
	LD	D,H		; DE=remaining amount to save
SA_LEN	CALL	SA_ROM		; Save header and data
	LD	HL,(HEADER+13)	; Get start of just saved block
	LD	DE,(HEADER+11)	; Get length just saved block
	ADD	HL,DE
	LD	(HEADER+13),HL	; Update address
	LD	HL,(LENGTH)	; Get current length
	AND	A
	SBC	HL,DE		; Subtract length just saved
	LD	(LENGTH),HL	; Update length
	LD	A,H
	OR	L
	JR	NZ,SA_LOOP	; Loop until all done blocks
	OR	D		; Check length of last block
	RET	Z		; Last block<256, is an EOF block
	LD	IX,HEADER	; Point to header
	LD	DE,17		; Header is 17 bytes
	XOR	A		; A=&00 for header
	CALL	#04C2		; Save header
	LD	DE,0
	XOR	A		; Has to be &00 as also parity byte
	JP	#04C2		; Save zero-byte EOF block

SA_ROM	LD	(HEADER+11),DE	; Set this block's length
	LD	HL,(HEADER+13)	; Get this block's address
	LD	IX,HEADER	; Point to header
	PUSH	HL		; Stack address
	JP	#0984		; Jump to save


DO_LOAD
LD_LOOP	LD	HL,0		; Use file's start address
	LD	(HEADER+11),HL	; Use file's length
	LD	IX,HEADER	; Point to header to search for
	CALL	#0761		; Wait for and load a block
	LD	A,(HEADER2+12)	; Get length high byte
	AND	A		; Last block has <256 bytes
	RET	Z		; No more to load
	LD	B,64		; 64 characters
LD_UP	LD	A,8		; CHR$8 - move back
	RST	#10		; Move up a line to overwrite
	DJNZ	LD_UP
	JR	LD_LOOP		; Loop until last block loaded

	DEFW	SAVE,0