; SAVE.S - *SAVE command using blocked tape save
; J.G.Harston, 25 June 1986
;
; Syntax: *SAVE filename START+LENGTH:BLKLEN
; v1.00 25-Jun-1986 Saves fixed 256-byte blocks, <256 for last block
; v1.01 23-Aug-1987 Saves a final zero-length block if last block not <256 bytes
;                   Skips spaces before calling SCANHEX
;                   Note, bad syntax not checked for, must be no space before '+'

; Block header:
; 00
; File type
; Filename
; Block length - 256+ for full block, <256 for last block
; Block start address
; Block extra address
;
; Block data:
; FF
; <data> as per length
;
; Block data if final block is not &00xx bytes long:
; 00

SCANHEX	EQU	#0025		; Scan hex from DE to HL, A=term char

	ORG	#5B00
SAVE	LD	HL,HEADER+1	; Point to filename
	LD	B,10
NAME	LD	A,(DE)		; Copy filename from DE
	CP	33
	JR	C,NAMEPAD
	LD	(HL),A
	INC	HL
	INC	DE
	DJNZ	NAME
	JR	NAMEOK
NAMEPAD	LD	A,32		; Pad with spaces
	LD	(HL),A
	INC	HL
	DJNZ	NAMEPAD
NAMEOK	CALL	SKIPSPC
	CALL	SCANHEX
	LD	(HEADER+13),HL	; Start
	LD	(HEADER+15),HL	; Extra
	CALL	SKIPSPC
	CALL	SKIPNXT		; Step past '+'
	CALL	SCANHEX		; Read length
	LD	(LENGTH),HL	; Length
	CALL	SKIPSPC
	CP	":"		; Any block length specified?
	JR	NZ,BLKOK	; No, use default
	CALL	SKIPNXT		; Step past ':'
	CALL	SCANHEX		; Read blocklen
	LD	(BLKLEN),HL
BLKOK	LD	A,3
	LD	(HEADER+0),A	; Filetype

SA_LOOP	LD	HL,(LENGTH)	; Get remaining length
	LD	DE,(BLKLEN)	; Prepare to save full BLKLEN bytes
	AND	A
	SBC	HL,DE		; Is remaining length<BLKLEN ?
	JR	NC,SA_LEN	; Still more blocks to save
	ADD	HL,DE		; HL=remaining amount to save
	LD	E,L
	LD	D,H		; DE=remaining amount to save
SA_LEN	CALL	SA_ROM		; Save header and data
	LD	HL,(HEADER+13)	; Get start of just saved block
	LD	DE,(HEADER+11)	; Get length just saved block
	ADD	HL,DE
	LD	(HEADER+13),HL	; Update address
	LD	HL,(LENGTH)	; Get current length
	AND	A
	SBC	HL,DE		; Subtract length just saved
	LD	(LENGTH),HL	; Update length
	LD	A,H
	OR	L
	JR	NZ,SA_LOOP	; Loop until all done blocks
	OR	D		; Check length of last block
	RET	Z		; Last block<256, is an EOF block
	LD	IX,HEADER	; Point to header
	LD	DE,17		; Header is 17 bytes
	XOR	A		; A=&00 for header
	CALL	#04C2		; Save header
	LD	DE,0
	XOR	A		; Has to be &00 as also parity byte
	JP	#04C2		; Save zero-byte EOF block

SA_ROM	LD	(HEADER+11),DE	; Set this block's length
	LD	HL,(HEADER+13)	; Get this block's address
	LD	IX,HEADER	; Point to header
	PUSH	HL		; Stack address
	JP	#0984		; Jump to save

SKIPNXT	INC	DE		; Step past char
SKIPSPC	LD	A,(DE)		; Get current char
	CP	" "
	JR	Z,SKIPNXT	; Step past spaces
	RET

BLKLEN	DEFW	512		; Maximum block size
START	EQU	BLKLEN+2	; Data start
LENGTH	EQU	BLKLEN+4	; Data length
HEADER	EQU	BLKLEN+6	; File header to save/load

	DEFW	SAVE,SAVE