Pathname

10 REM > BLib.Pathname 1.01 19Sep1992

20 REM v1.00 19Sep1992 JGH: Initial version

30 REM v1.01 15Mar1995 JGH: Functions named Path_*

40 ;!Keep FNPath_Full:REM!Keep FNPath_Full

50 :

60 REM Directory Pathname Functions

70 REM ============================

80 :

90 REM FNPath_Name - Return pathname with drive number or name if no number

100 REM FNPath_Full - Returns full pathname with diskname

110 REM The returned pathname can be used to select the directory with *DIR

120 REM --------------------------------------------------------------------

130 :

140 DEFFNPath_Name:A%=6

150 DEFFNPath_Full:A%=&106

160 LOCAL n$,p$:REPEAT:X%!1=name%:CALL &FFD1

170 ?(name%+2+?name%+?(name%+?name%+1))=13

180 n$=$(name%+2+?name%):*DIR ^

190 n$=LEFT$(n$,INSTR(n$+" "," ")-1)

200 p$=n$+"."+p$:UNTILn$="$"ORn$="&"

210 p$=LEFT$(p$,LENp$-1):OSCLI"DIR "+p$

220 IFA%=6:X%!1=name%:CALL &FFD1:?(name%+1+?name%)=13:n$=$(name%+1):IFn$<>"":=":"+n$+"."+p$

230 X%!1=name%:A%=5:CALL &FFD1

240 ?(name%+1+?name%)=13:n$=$(name%+1)

250 n$=LEFT$(n$,INSTR(n$+" "," ")-1):=":"+n$+"."+p$

260 :

270 :

280 REM FNPath_Lib - Return library pathname

290 REM ------------------------------------

300 :

310 DEFFNPath_Lib

320 LOCAL a$,b$:a$=FNPath_Name:*DIR %

330 b$=FNPath_Name:OSCLI"DIR "+a$:=b$

340 :

350 :

360 REM FNPath_LibFull - Return full library pathname

370 REM ---------------------------------------------

380 :

390 DEFFNPath_LibFull

400 LOCAL a$,b$:a$=FNPath_Name:*DIR %

410 b$=FNPath_Full:OSCLI"DIR "+a$:=b$

420 :

430 :

440 REM FNPath_URD - Return URD pathname

450 REM --------------------------------

460 :

470 DEFFNPath_URD

480 LOCAL a$,b$:a$=FNPath_Name:*DIR &

490 b$=FNPath_Name:OSCLI"DIR "+a$:=b$

500 :

510 :

520 REM FNPath_URDFull - Return full URD pathname

530 REM -----------------------------------------

540 :

550 DEFFNPath_URDFull

560 LOCAL a$,b$:a$=FNPath_Name:*DIR &

570 b$=FNPath_Full:OSCLI"DIR "+a$:=b$

580 :